웹딘프로아밥 Application Parameters 전체 세팅 WD_GLOBAL_SETTING (http://boy0.tistory.com/18)
와 같은 내용에 업그레이드 된 7.02 기준의 문서입니다.

http://www.sdn.sap.com/irj/scn/go/portal/prtroot/docs/library/uuid/9010b5e3-75b3-2e10-1cb1-c5c8a8b82672
7.02에서 변화가 보이네요.
전체 세팅하는 프로그램도 WD_GLOBAL_SETTING 에서 WD_GLOBAL_PARAMETERS 으로 변경되었습니다.

 

구글 검색하면 많이 나오는 내용이긴 합니다만, 웹딘프로아밥에서 필수값 체크하는 방법입니다.

http://www.sdn.sap.com/irj/scn/index?rid=/library/uuid/207e4467-227e-2e10-6fbb-e3a562038296

링크에 나온 내용처럼 wdDoBeforeAction에 넣어도 되고,
그냥 필요할때 이벤트처리 메소드에 넣어도 무방합니다.

cl_wd_dynamic_tool=>check_mandatory_attr_on_view( wd_this->wd_get_api( ) ).

중요한 키워드는 사실 위 한줄이죠.
 

ABAP 에는 pointer 개념의 reference 와 field-symbol 있는데,
그 사용법이 참... 까다롭네요.

reference는 주로 파라미터 전달을 위해 사용합니다. 참조 주소를 전달할 수 있기 때문이죠.
generic reference로 값을 받으면 읽기 위해선 field-symbol 을 사용해야 한다는 부분을 주의하세요.

REPORT  y_ref_fs_data.




DATA: lt_sflight TYPE TABLE OF sflight,
      ls_sflight TYPE sflight,
      lv_carrid TYPE sflight-carrid,
      ltr_sflight TYPE REF TO sflight_tab1,
      lsr_sflight TYPE REF TO sflight,
      lvr_carrid TYPE REF TO sflight-carrid,
      lr_data TYPE REF TO data.   " generic type ref
FIELD-SYMBOLS: <lt_sflight> TYPE sflight_tab1,
               <ls_sflight> TYPE sflight,
               <lv_carrid> TYPE sflight-carrid,
               <lt_data> TYPE ANY TABLE, " generic table type <fs>
               <ls_data> TYPE data,  " generic type <fs>
               <l_data> TYPE data.   " generic type <fs>


 

* select data.
SELECT * FROM sflight INTO TABLE lt_sflight.
READ TABLE lt_sflight INDEX 1 INTO ls_sflight.
lv_carrid = ls_sflight-carrid.


 

* 1. data -->  ref
GET REFERENCE OF lt_sflight INTO ltr_sflight.
GET REFERENCE OF ls_sflight INTO lsr_sflight.
GET REFERENCE OF lv_carrid INTO lvr_carrid.
*  or
GET REFERENCE OF lt_sflight INTO lr_data.
GET REFERENCE OF ls_sflight INTO lr_data.
GET REFERENCE OF lv_carrid INTO lr_data.
** error !!! Syntax Error !!!
*GET REFERENCE OF ls_sflight INTO ltr_sflight.
*GET REFERENCE OF lv_carrid INTO ltr_sflight.
*GET REFERENCE OF lv_carrid INTO lsr_sflight.


 

* 2. ref  -->  <fs>
ASSIGN ltr_sflight->* TO <lt_sflight>.
ASSIGN lsr_sflight->* TO <ls_sflight>.
ASSIGN lvr_carrid->* TO <lv_carrid>.
*  or
ASSIGN ltr_sflight->* TO <l_data>.
ASSIGN lsr_sflight->* TO <l_data>.
ASSIGN lvr_carrid->* TO <l_data>.
*  or
ASSIGN lr_data->* TO <l_data>.
** error !!! Syntax Error !!!
*ASSIGN lsr_sflight->* TO <lt_sflight>.
*ASSIGN lvr_carrid->* TO <lt_sflight>.
** error !!! Short Dump !!!
*ASSIGN lr_data->* TO <lt_sflight>.


 

* 3. <fs>  -->  data
MOVE <lt_sflight> TO lt_sflight.   " lt_sflight = <lt_sflight>.
MOVE <ls_sflight> TO ls_sflight.   " ls_sflight = <ls_sflight>.
MOVE <lv_carrid> TO lv_carrid.    " lv_carrid = <lv_carrid>.
* or
MOVE <l_data> TO lv_carrid.     " lv_carrid = <l_data>.
** error !!! Syntax Error !!!
*MOVE <lt_sflight> TO ls_sflight.   " ls_sflight = <lt_sflight>.
** error !!! Short Dump !!!
*MOVE <l_data> TO lt_sflight.    " lt_sflight = <l_data>.
*MOVE <l_data> TO ls_sflight.    " ls_sflight = <l_data>.


 

* 4. data -->  <fs>
ASSIGN lt_sflight TO <lt_sflight>.
ASSIGN ls_sflight TO <ls_sflight>.
ASSIGN lv_carrid TO <lv_carrid>.
*  or
ASSIGN lt_sflight TO <l_data>.
ASSIGN ls_sflight TO <l_data>.
ASSIGN lv_carrid TO <l_data>.
** error !!! Syntax Error !!!
*ASSIGN ls_sflight TO <lt_sflight>.
*ASSIGN lv_carrid TO <lt_sflight>.


 

* 5. <fs>  -->  ref
GET REFERENCE OF <lt_sflight> INTO ltr_sflight.
GET REFERENCE OF <ls_sflight> INTO lsr_sflight.
GET REFERENCE OF <lv_carrid> INTO lvr_carrid.
*  or
GET REFERENCE OF <lt_sflight> INTO lr_data.
GET REFERENCE OF <ls_sflight> INTO lr_data.
GET REFERENCE OF <l_data> INTO lr_data.
** error !!! Syntax Error !!!
*GET REFERENCE OF <lt_sflight> INTO lsr_sflight.
*GET REFERENCE OF <lt_sflight> INTO lvr_carrid.
** error !!! Short Dump !!!
*GET REFERENCE OF <ls_sflight> INTO ltr_sflight.
*GET REFERENCE OF <lv_carrid> INTO ltr_sflight.
*GET REFERENCE OF <lv_carrid> INTO lsr_sflight.


 

* 6. ref  -->  data
MOVE ltr_sflight->* TO lt_sflight.   " lt_sflight = ltr_sflight->*.
MOVE lsr_sflight->* TO ls_sflight.   " ls_sflight = lsr_sflight->*.
MOVE lvr_carrid->* TO lv_carrid.     " lv_carrid = lvr_carrid->*.
** error !!! Syntax Error !!!
*MOVE lr_data->* TO lt_sflight.   " lt_sflight = lr_data->*.
*MOVE lr_data->* TO ls_sflight.   " ls_sflight = lr_data->*.
*MOVE lr_data->* TO lv_carrid.    " lv_carrid = lr_data->*.





* 7. How to read generic ref (table)
GET REFERENCE OF lt_sflight INTO lr_data.   " generic ref
* -->  lt_sflight
ASSIGN lr_data->* TO <l_data>.
MOVE <l_data> TO lt_sflight.   " lt_sflight = <l_data>.
*  or
ASSIGN lr_data->* TO <lt_data>.
MOVE <lt_data> TO lt_sflight.   " lt_sflight = <lt_data>.
*  or
ASSIGN lr_data->* TO <lt_sflight>.
MOVE <lt_sflight> TO lt_sflight.   " lt_sflight = <lt_sflight>.
* -->  ls_sflight
ASSIGN lr_data->* TO <lt_data>.
LOOP AT <lt_data> ASSIGNING <ls_data>.
  MOVE <ls_data> TO ls_sflight.   " ls_sflight = <l_data>.
ENDLOOP.
*  or
ASSIGN lr_data->* TO <lt_sflight>.
LOOP AT <lt_sflight> ASSIGNING <ls_sflight>.
  MOVE <ls_sflight> TO ls_sflight.    " ls_sflight = <ls_sflight>.
ENDLOOP.
* -->  lv_carrid
ASSIGN lr_data->* TO <lt_data>.
LOOP AT <lt_data> ASSIGNING <ls_data>.
  ASSIGN COMPONENT 'CARRID' OF STRUCTURE <ls_data> TO <l_data>.
  MOVE <l_data> TO lv_carrid.   " lv_carrid = <l_data>.
ENDLOOP.
*  or
ASSIGN lr_data->* TO <lt_sflight>.
LOOP AT <lt_sflight> ASSIGNING <ls_sflight>.
  ASSIGN COMPONENT 'CARRID' OF STRUCTURE <ls_sflight> TO <lv_carrid>.
  MOVE <lv_carrid> TO lv_carrid.    " lv_carrid = <lv_carrid>.
ENDLOOP.


 

* 8. How to read generic ref (structure)
GET REFERENCE OF ls_sflight INTO lr_data.   " generic ref
* -->  ls_sflight
ASSIGN lr_data->* TO <ls_data>.
MOVE <ls_data> TO ls_sflight.   " ls_sflight = <ls_data>.
*  or
ASSIGN lr_data->* TO <ls_sflight>.
MOVE <ls_sflight> TO ls_sflight.    " ls_sflight = <ls_sflight>
* -->  lv_carrid
ASSIGN lr_data->* TO <ls_data>.
ASSIGN COMPONENT 'CARRID' OF STRUCTURE <ls_data> TO <l_data>.
MOVE <l_data> TO lv_carrid.   " lv_carrid = <l_data>.
*  or
ASSIGN lr_data->* TO <ls_data>.
ASSIGN COMPONENT 'CARRID' OF STRUCTURE <ls_data> TO <lv_carrid>.
MOVE <lv_carrid> TO lv_carrid.    " lv_carrid = <lv_carrid>.


 

* 9. How to read generic ref (variable)
GET REFERENCE OF lv_carrid INTO lr_data.   " generic ref
* -->  lv_carrid
ASSIGN lr_data->* TO <l_data>.
MOVE <l_data> TO lv_carrid.   " lv_carrid = <l_data>.
*  or
ASSIGN lr_data->* TO <lv_carrid>.
MOVE <lv_carrid> TO lv_carrid.    " lv_carrid = <lv_carrid>.


 

** End.

http://archive.sap.com/documents/docs/DOC-2236

Chapter 5. User Interface and User Experience Guidelines for Best-Built Applications 

아래 첨부파일은 SAPLINK 프로그램을 이용하여 Import Slinkee 하면 볼 수 있습니다.

애플리케이션은 두개 입니다.

1. 본 창닫기 테스트

2. 내부 팝업 닫기 테스트

본 창 닫기를 위한 작업입니다. (내부 팝업엔 필요없음)
윈도우에 아웃바운드 플러그를 하나 만들고 타입은 Exit 으로하고 파라미터 CLOSE_WINDOW를 추가합니다.

닫는 로직은 이렇습니다.

METHOD close_popup .
* 하나의 메소드로 통합된 창닫기.
* 이 로직으로 내부 팝업, 본 창 무엇으로 사용되더라도 닫을 수 있다.

  DATA lo_api_view TYPE REF TO if_wd_view_controller.
   lo_api_view = wd_this->wd_get_api( ).

  DATA lo_api_window TYPE REF TO if_wd_window_controller.
   lo_api_window = lo_api_view->get_embedding_window_ctlr( ).

* lo_window 는 내부 팝업인 경우에 값이 있다.
  DATA: lo_window TYPE REF TO if_wd_window.
   lo_window = lo_api_window->get_window( ).

  IF lo_window IS BOUND.
* 내부 팝업 닫기
    lo_window->close( ).
  ELSE.
* 본 창은 lo_window가 없으므로 윈도우의 outbound plug를 호출하여 창을 닫는다.
* wd_this->fire_close_plg( close_window = abap_true ).

    DATA: lt_param TYPE wdr_event_parameter_list,
     ls_param LIKE LINE OF lt_param.

    ls_param-name = 'CLOSE_WINDOW'.
    GET REFERENCE OF abap_true INTO ls_param-value.
    INSERT ls_param INTO TABLE lt_param.

    lo_api_window->fire_plug(
      EXPORTING
        parameters = lt_param " Parameter of Outbound Plug
         plug_name = 'CLOSE' " Web Dynpro: Runtime Structure of In/Outbound Plugs
    ).
  ENDIF.

ENDMETHOD.