boy0

CONVERSION_EXIT 컨버전루틴 총정리 (feat. 알파컨버전)

Derby — Fri, 20 Jun 2025 13:35:15 +0900

도메인 속성중에 컨버전루틴을 설정하는 곳이 있습니다.

Output Chracteristics 아래에 Routine.

ALPHA 처럼 5글자로 구성됩니다.

알파컨버전은 대표적인 컨버전루틴(=컨버전엑싯)입니다.

알파컨버전이 걸려 있으면 내부값(디버깅에서볼때)은 앞에 0이 채워져 있습니다.

외부표시(화면에서볼때)는 앞에 0이 지워져 있습니다.

예를들어 내부값은 '0000012345' 이고 외부표시는 '12345' 입니다.

이렇게 내부값과 외부표시를 다르게 사용하는걸 컨버전루틴이라고 합니다.

알파컨버전은 왜 쓰는걸까요?

쓸모가 있습니다. 문자를 숫자처럼 정렬 하기 위해서 입니다.

예를들어 '9' 와 '10' 을 크기 비교하여 정렬한다고 하면 문자 기준으로는 '10' 다음 '9' 순서로 정렬이 됩니다.

하지만 앞에 0을 채워서 같은 길이를 가진다면 '9' 다음 '10' 순서로 정렬이 될 것입니다.

날짜와 시간 타입을 살펴 보겠습니다.

도메인에는 컨버전루틴이 없습니다.

내부값이 '99991231' 이면 외부표시는 '9999.12.31' 로 나오는건 어떻게 된걸까요?

그이유는 User Profile의 Date Format 설정에 맞게 자동 컨버전되기 때문입니다.

컨버전루틴을 만드는 방법은?

만드는 방법이 독특한데요. 규칙에 맞게 펑션 2개를 만들면 됩니다.

알파컨버젼은 위 2개 펑션으로 구성되어 있습니다.

명명 규칙은 CONVERSION_EXIT_컨버전명_INPUT 과 CONVERSION_EXIT_컨버전명_OUTPUT 입니다.

알파컨버전의 펑션을 복사하여 만드세요.

도메인에 연결을 합니다.

테스트 해보니 잘 되네요.

SAP ABAP Currency 총정리

Derby — Fri, 15 Nov 2024 15:47:29 +0900

개념:
ABAP에서 금액 필드(CURR:Currency field)는 통화키 필드(CUKY:Currency key)가 연결되어 있어야 합니다.
각 통화에 따라 금액 필드의 소수점을 해석하는 방법이 다릅니다.
예를 들어 금액 필드의 1.00 이라는 값을 USD 통화로는 1$로 해석하고 KRW 통화로는 100원으로 해석합니다.
금액 필드의 값을 통화 없이 값 그대로 사용하게 되면 100원을 1원으로 보게 됩니다.
금액에는 반드시 통화가 있어야 합니다.
USD 통화일때는 무시해도 되는 함정이 있어서 USD만 테스트하는 실수를 주의해야 합니다.
흔한 오류:
USD는 잘 되는데 KRW 통화일때 1/100 으로 표시 또는 처리 되어서 곱하기 100 을 하도록 로직 작성한다.
인터페이스 받아서 SAP에 저장하는데 KRW 통화일때 100배로 처리 되어서 나누기 100을 하도록 로직 작성한다.
무엇이 문제인가:
KRW인지 체크하여 곱하기 100, 나누기 100을 하면 안됩니다.
표준적인 방법으로 통화를 적용하여 계산하세요.
왜 이렇게 하나요:
각 통화별로 금액의 최소 단위가 다르기 때문입니다.
USD는 소수점 아래 2 자리까지 표시를 합니다. 0.01$(=1센트) 가 최소단위 입니다.
KRW는 소수점이 없습니다. 1원이 최소단위 입니다. 소수점을 입력하면 안됩니다.
이런 차이를 수용하기 위한 방법입니다.
관련 테이블:
통화 마스터 테이블 TCURC 별 내용 없음
통화별 소수점 자리수 테이블 TCURX 기본값 2인 경우 생략되어 있음.
내부(SAP) -> 외부:
WRITE 구문 (추천)
BAPI_CURRENCY_CONV_TO_EXTERNAL
CURRENCY_AMOUNT_SAP_TO_DISPLAY
외부 -> 내부(SAP):
BAPI_CURRENCY_CONV_TO_INTERNAL
CURRENCY_AMOUNT_DISPLAY_TO_SAP
내부 외부 변환이 없어도 자동으로 적용되는 경우:
스트럭쳐에서 통화필드가 연결되어 있는 금액 필드를 SAP 화면에 표시하면 자동 적용.
변환이 필요한 경우:
고정된 통화라서 통화필드가 연결되지 않은 금액필드를 화면에 표시하는 경우.
금액을 인터페이스로 다른 시스템에 주거나 받는 경우.
BDC로 작성한 프로그램에서 금액 입력시 외부 값으로 바꿔야함.
금액 필드를 숫자 필드로 타입 변환할때 외부 값으로 바꿔야함.
숫자 필드로 입력 받아서 DB에는 금액필드로 저장하는 경우 내부 값으로 바꿔야함.

SY-DATUM 과 SY-DATLO 차이

Derby — Thu, 4 Jan 2024 16:41:34 +0900

타임존이 시스템(서버) 기준:

날짜: SY-DATUM

시간: SY-UZEIT

타임존: 펑션 호출 GET_SYSTEM_TIMEZONE 또는 테이블 TTZCU

타임존이 사용자(로컬) 기준:

날짜: SY-DATLO

시간: SY-TIMLO

타임존: SY-ZONLO

타임존이 UTC(세계표준시) 기준:

날짜: GET TIME STAMP FIELD lv_ts. lv_ts(8)

시간: GET TIME STAMP FIELD lv_ts. lv_ts+8(6)

타임존: UTC

타임존이 다른 경우의 변환 로직:

CONVERT DATE lv_date_from TIME lv_time_from INTO TIME STAMP lv_ts TIME ZONE lv_tz_from.
CONVERT TIME STAMP lv_ts TIME ZONE lv_tz_to INTO DATE lv_date_to TIME lv_time_to.

타임존에 대한 이해가 필요한 경우 아래 글 참고:

https://boy0.tistory.com/181

ABAP TIMESTAMP 총정리

타임스탬프로 사용되는 타입은 두가지가 있습니다. TIMESTAMP : 15자리 YYYYMMDDhhmmss TIMESTAMPL : 21자리 YYYYMMDDhhmmss.ssssss 주로 사용하는 15자리 TIMESTAMP 를 기준으로 설명하겠습니다. 예를 들어 인천 에서

boy0.tistory.com

abap으로 open API (RESTful) 호출하기

Derby — Wed, 20 Dec 2023 12:53:50 +0900

RESTful API 호출하는 예제 프로그램.

*&---------------------------------------------------------------------*
*& Report ZRESTFUL_API
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
REPORT zrestful_api.

PARAMETERS: p_string TYPE string.

TYPES: BEGIN OF ts_req,
         BEGIN OF argument,
           type     TYPE string,
           question TYPE string,
         END OF argument,
       END OF ts_req,
       BEGIN OF ts_res_irinfo,
         wiki_title TYPE string,
         sent       TYPE string,
         url        TYPE string,
       END OF ts_res_irinfo,
       BEGIN OF ts_res_answerinfo,
         rank       TYPE i,
         answer     TYPE string,
         confidence TYPE i,
         url        TYPE STANDARD TABLE OF string WITH DEFAULT KEY,
       END OF ts_res_answerinfo,
       BEGIN OF ts_res,
         result TYPE string,
         BEGIN OF return_object,
           BEGIN OF wikiinfo,
             irinfo     TYPE STANDARD TABLE OF ts_res_irinfo WITH DEFAULT KEY,
             answerinfo TYPE STANDARD TABLE OF ts_res_answerinfo WITH DEFAULT KEY,
           END OF wikiinfo,
         END OF return_object,
       END OF ts_res.

DATA: lv_url      TYPE string,
      ls_req      TYPE ts_req,
      lv_req_json TYPE string,
      lo_client   TYPE REF TO if_http_client,
      lv_message  TYPE string,
      lv_res_json TYPE string,
      ls_res      TYPE ts_res.

* 위키백과 QA API
* https://aiopen.etri.re.kr/guide/WikiQA
lv_url = |http://aiopen.etri.re.kr:8000/WikiQA|.
ls_req-argument-type = 'hybridqa'.
ls_req-argument-question = p_string.

"REQ to json
/ui2/cl_json=>serialize(
  EXPORTING
    data             = ls_req             " Data to serialize
    pretty_name      = /ui2/cl_json=>pretty_mode-low_case      " Pretty Print property names
  RECEIVING
    r_json           = lv_req_json           " JSON string
).

"HTTP create
cl_http_client=>create_by_url(
  EXPORTING
    url                    = lv_url             " URL
  IMPORTING
    client                 = lo_client          " HTTP Client Abstraction
  EXCEPTIONS
    argument_not_found     = 1               " Communication parameter (host or service) not available
    plugin_not_active      = 2               " HTTP/HTTPS communication not available
    internal_error         = 3               " Internal error (e.g. name too long)
    pse_not_found          = 4               " PSE not found
    pse_not_distrib        = 5               " PSE not distributed
    pse_errors             = 6               " General PSE error
    OTHERS                 = 7
).
IF sy-subrc <> 0.
  MESSAGE 'HTTP error' TYPE 'E'.
  RETURN.
ENDIF.

" HTTP request
lo_client->request->set_method(
    method = if_http_request=>co_request_method_post
).
lo_client->request->set_header_field(
  EXPORTING
    name  = 'Content-Type'
    value = 'application/json'
).
lo_client->request->set_header_field(
  EXPORTING
    name  = 'Authorization'
    value = 'cfd006b6-7766-42ca-88fc-3cd1e1c357f7'
).
lo_client->request->set_cdata(
  EXPORTING
    data   = lv_req_json
).

"HTTP send
lo_client->send(
  EXCEPTIONS
    http_communication_failure = 1                  " Communication Error
    http_invalid_state         = 2                  " Invalid state
    http_processing_failed     = 3                  " Error when processing method
    http_invalid_timeout       = 4                  " Invalid Time Entry
    OTHERS                     = 5
).
IF sy-subrc <> 0.
  lo_client->get_last_error(
    IMPORTING
      message        = lv_message
  ).
  MESSAGE lv_message TYPE 'E'.
  RETURN.
ENDIF.

"HTTP receive
lo_client->receive(
  EXCEPTIONS
    http_communication_failure = 1 " Communication Error
    http_invalid_state         = 2 " Invalid state
    http_processing_failed     = 3 " Error when processing method
    OTHERS                     = 4
).
IF sy-subrc <> 0.
  lo_client->get_last_error(
    IMPORTING
      message        = lv_message
  ).
  MESSAGE lv_message TYPE 'E'.
  RETURN.
ENDIF.

"HTTP response
IF lo_client->response IS NOT INITIAL.
  lv_res_json = lo_client->response->get_cdata( ).
ENDIF.

"json to RES
/ui2/cl_json=>deserialize(
  EXPORTING
    json             = lv_res_json             " JSON string
  CHANGING
    data             = ls_res             " Data to serialize
).
*BREAK-POINT.

IF ls_res-return_object-wikiinfo-answerinfo IS NOT INITIAL.
  cl_demo_output=>display( ls_res-return_object-wikiinfo-answerinfo[ 1 ]-answer ).
ENDIF.

abap으로 ZIP 압축하기

Derby — Tue, 17 Oct 2023 15:33:22 +0900

ZIP 압축하는 예제 프로그램.

*&---------------------------------------------------------------------*
*& Report ZZIP
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
REPORT zzip.

DATA: lt_file_table TYPE filetable,
      ls_file_table TYPE file_table,
      lv_rc         TYPE i,
      lv_filename   TYPE string,
      lv_path       TYPE string,
      lv_fullpath   TYPE string,
      lv_filelength TYPE i,
      lt_temptable  TYPE w3mimetabtype,
      lv_xstring    TYPE xstring,
      lo_zip        TYPE REF TO cl_abap_zip.

cl_gui_frontend_services=>file_open_dialog(
  EXPORTING
*    window_title            =                  " Title Of File Open Dialog
*    default_extension       =                  " Default Extension
*    default_filename        =                  " Default File Name
*    file_filter             =                  " File Extension Filter String
*    with_encoding           =                  " File Encoding
*    initial_directory       =                  " Initial Directory
    multiselection          = abap_true                 " Multiple selections poss.
  CHANGING
    file_table              = lt_file_table                 " Table Holding Selected Files
    rc                      = lv_rc                 " Return Code, Number of Files or -1 If Error Occurred
*    user_action             =                  " User Action (See Class Constants ACTION_OK, ACTION_CANCEL)
*    file_encoding           =
  EXCEPTIONS
    file_open_dialog_failed = 1                " "Open File" dialog failed
    cntl_error              = 2                " Control error
    error_no_gui            = 3                " No GUI available
    not_supported_by_gui    = 4                " GUI does not support this
    OTHERS                  = 5
).
IF sy-subrc <> 0.
  MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
    WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.

CHECK: lt_file_table IS NOT INITIAL.
CREATE OBJECT lo_zip.
lo_zip->support_unicode_names = abap_true.

LOOP AT lt_file_table INTO ls_file_table.
  CLEAR: lv_filename, lv_filelength, lt_temptable, lv_xstring.

  lv_filename = ls_file_table-filename.
  cl_gui_frontend_services=>gui_upload(
    EXPORTING
      filename                = lv_filename            " Name of file
      filetype                = 'BIN'            " File Type (ASCII, Binary)
*      has_field_separator     = space            " Columns Separated by Tabs in Case of ASCII Upload
*      header_length           = 0                " Length of Header for Binary Data
*      read_by_line            = 'X'              " File Written Line-By-Line to the Internal Table
*      dat_mode                = space            " Numeric and date fields are in DAT format in WS_DOWNLOAD
*      codepage                =                  " Character Representation for Output
*      ignore_cerr             = abap_true        " Ignore character set conversion errors?
*      replacement             = '#'              " Replacement Character for Non-Convertible Characters
*      virus_scan_profile      =                  " Virus Scan Profile
    IMPORTING
      filelength              = lv_filelength                  " File Length
*      header                  =                  " File Header in Case of Binary Upload
    CHANGING
      data_tab                = lt_temptable                 " Transfer table for file contents
*      isscanperformed         = space            " File already scanned
    EXCEPTIONS
      file_open_error         = 1                " File does not exist and cannot be opened
      file_read_error         = 2                " Error when reading file
      no_batch                = 3                " Cannot execute front-end function in background
      gui_refuse_filetransfer = 4                " Incorrect front end or error on front end
      invalid_type            = 5                " Incorrect parameter FILETYPE
      no_authority            = 6                " No upload authorization
      unknown_error           = 7                " Unknown error
      bad_data_format         = 8                " Cannot Interpret Data in File
      header_not_allowed      = 9                " Invalid header
      separator_not_allowed   = 10               " Invalid separator
      header_too_long         = 11               " Header information currently restricted to 1023 bytes
      unknown_dp_error        = 12               " Error when calling data provider
      access_denied           = 13               " Access to file denied.
      dp_out_of_memory        = 14               " Not enough memory in data provider
      disk_full               = 15               " Storage medium is full.
      dp_timeout              = 16               " Data provider timeout
      not_supported_by_gui    = 17               " GUI does not support this
      error_no_gui            = 18               " GUI not available
      OTHERS                  = 19
  ).
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
      WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

  CALL FUNCTION 'SCMS_BINARY_TO_XSTRING'
    EXPORTING
      input_length = lv_filelength
*     first_line   = 0
*     last_line    = 0
    IMPORTING
      buffer       = lv_xstring
    TABLES
      binary_tab   = lt_temptable
    EXCEPTIONS
      failed       = 1
      OTHERS       = 2.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
      WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

  CALL FUNCTION 'SO_SPLIT_FILE_AND_PATH'
    EXPORTING
      full_name     = ls_file_table-filename
    IMPORTING
      stripped_name = lv_filename
    EXCEPTIONS
      x_error       = 1
      OTHERS        = 2.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
      WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

  lo_zip->add(
    EXPORTING
      name           = lv_filename
      content        = lv_xstring
*      compress_level = 6                " Level of Compression
  ).

ENDLOOP.

lv_xstring = lo_zip->save( ).

CALL FUNCTION 'SCMS_XSTRING_TO_BINARY'
  EXPORTING
    buffer        = lv_xstring
  IMPORTING
    output_length = lv_filelength
  TABLES
    binary_tab    = lt_temptable.

cl_gui_frontend_services=>file_save_dialog(
  EXPORTING
*    window_title              =                  " Window Title
    default_extension         = 'ZIP'                 " Default Extension
    default_file_name         = 'a.zip'                 " Default File Name
*    with_encoding             =
    file_filter               = 'ZIP(*.ZIP)|*.ZIP'                 " File Type Filter Table
*    initial_directory         =                  " Initial Directory
*    prompt_on_overwrite       = 'X'
  CHANGING
    filename                  = lv_filename                 " File Name to Save
    path                      = lv_path                 " Path to File
    fullpath                  = lv_fullpath                 " Path + File Name
*    user_action               =                  " User Action (C Class Const ACTION_OK, ACTION_OVERWRITE etc)
*    file_encoding             =
  EXCEPTIONS
    cntl_error                = 1                " Control error
    error_no_gui              = 2                " No GUI available
    not_supported_by_gui      = 3                " GUI does not support this
    invalid_default_file_name = 4                " Invalid default file name
    OTHERS                    = 5
).
IF sy-subrc <> 0.
  MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
    WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.

cl_gui_frontend_services=>gui_download(
  EXPORTING
    bin_filesize              = lv_filelength                     " File length for binary files
    filename                  = lv_fullpath                     " Name of file
    filetype                  = 'BIN'                " File type (ASCII, binary ...)
*    append                    = space                " Character Field of Length 1
*    write_field_separator     = space                " Separate Columns by Tabs in Case of ASCII Download
*    header                    = '00'                 " Byte Chain Written to Beginning of File in Binary Mode
*    trunc_trailing_blanks     = space                " Do not Write Blank at the End of Char Fields
*    write_lf                  = 'X'                  " Insert CR/LF at End of Line in Case of Char Download
*    col_select                = space                " Copy Only Selected Columns of the Table
*    col_select_mask           = space                " Vector Containing an 'X' for the Column To Be Copied
*    dat_mode                  = space                " Numeric and date fields are in DAT format in WS_DOWNLOAD
*    confirm_overwrite         = space                " Overwrite File Only After Confirmation
*    no_auth_check             = space                " Switch off Check for Access Rights
*    codepage                  =                      " Character Representation for Output
*    ignore_cerr               = abap_true            " Ignore character set conversion errors?
*    replacement               = '#'                  " Replacement Character for Non-Convertible Characters
*    write_bom                 = space                " If set, writes a Unicode byte order mark
*    trunc_trailing_blanks_eol = 'X'                  " Remove Trailing Blanks in Last Column
*    wk1_n_format              = space
*    wk1_n_size                = space
*    wk1_t_format              = space
*    wk1_t_size                = space
*    show_transfer_status      = 'X'                  " Enables suppression of transfer status message
*    fieldnames                =                      " Table Field Names
*    write_lf_after_last_line  = 'X'                  " Writes a CR/LF after final data record
*    virus_scan_profile        = '/SCET/GUI_DOWNLOAD' " Virus Scan Profile
*  IMPORTING
*    filelength                =                      " Number of bytes transferred
  CHANGING
    data_tab                  = lt_temptable                     " Transfer table
  EXCEPTIONS
    file_write_error          = 1                    " Cannot write to file
    no_batch                  = 2                    " Cannot execute front-end function in background
    gui_refuse_filetransfer   = 3                    " Incorrect Front End
    invalid_type              = 4                    " Invalid value for parameter FILETYPE
    no_authority              = 5                    " No Download Authorization
    unknown_error             = 6                    " Unknown error
    header_not_allowed        = 7                    " Invalid header
    separator_not_allowed     = 8                    " Invalid separator
    filesize_not_allowed      = 9                    " Invalid file size
    header_too_long           = 10                   " Header information currently restricted to 1023 bytes
    dp_error_create           = 11                   " Cannot create DataProvider
    dp_error_send             = 12                   " Error Sending Data with DataProvider
    dp_error_write            = 13                   " Error Writing Data with DataProvider
    unknown_dp_error          = 14                   " Error when calling data provider
    access_denied             = 15                   " Access to file denied.
    dp_out_of_memory          = 16                   " Not enough memory in data provider
    disk_full                 = 17                   " Storage medium is full.
    dp_timeout                = 18                   " Data provider timeout
    file_not_found            = 19                   " Could not find file
    dataprovider_exception    = 20                   " General Exception Error in DataProvider
    control_flush_error       = 21                   " Error in Control Framework
    not_supported_by_gui      = 22                   " GUI does not support this
    error_no_gui              = 23                   " GUI not available
    OTHERS                    = 24
).
IF sy-subrc <> 0.
  MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
    WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.

MDG staging table 가비지 데이터 삭제 처리 프로그램

Derby — Thu, 15 Jun 2023 12:50:35 +0900

알 수 없는 이유로 데이터가 꼬여서 덤프 에러 Exception condition "NO_KEY" triggered 발생하곤 합니다.

가비지 데이터 정리 프로그램 만들어 보았습니다.

코드:

*&---------------------------------------------------------------------*
*& Report ZMDP_ADJUST_STAGING
*&---------------------------------------------------------------------*
*& MDG staging table 가비지 데이터 삭제 처리 프로그램
*&---------------------------------------------------------------------*
REPORT zmdp_adjust_staging LINE-SIZE 250.

DATA : lt_message           TYPE usmd_t_message,
       ls_message           TYPE usmd_s_message,
       lt_model             TYPE TABLE OF usmd_model,
       lv_model             TYPE usmd_model,
       lo_model_gen_adapter TYPE REF TO if_usmd_model_gen_adapter,
       ls_log_phys_name     TYPE if_usmd_model_gen_adapter=>s_log_phys_name,
       lt_log_phys_name     TYPE if_usmd_model_gen_adapter=>t_log_phys_name,
       lv_entity            TYPE string,
       lv_select            TYPE string,
       lv_table             TYPE string,
       lv_key_field         TYPE string,
*       lt_range_key_value   TYPE RANGE OF usmd_tech_key,
       lt_key_value         TYPE TABLE OF usmd_tech_key,
       lv_key_value         TYPE usmd_tech_key,
       lv_usmd_value        TYPE usmd_value,
       lt_cr                TYPE TABLE OF usmd_crequest,
       lv_cr                TYPE usmd_crequest,
       lt_usmd1213          TYPE TABLE OF usmd1213,
       ls_usmd1213          TYPE usmd1213,
       lv_flag_del          TYPE flag,
       lv_where             TYPE string,
       lv_key_json          TYPE string,
       lr_data              TYPE REF TO data,
       lv_error             TYPE char1,
       lv_index             TYPE i.

FIELD-SYMBOLS: <lt_data> TYPE tabel,
               <ls_data> TYPE data,
               <lv_data> TYPE data.

*--------------------------------------------------------------------*
" 모델 검색
SELECT-OPTIONS so_model FOR lv_model MATCHCODE OBJECT zmdph_model.



*--------------------------------------------------------------------*
START-OF-SELECTION.

*--------------------------------------
  " 활성 상태의 모델정보 검색
  SELECT usmd_model
    INTO TABLE lt_model
    FROM usmd001c
   WHERE usmd_model IN so_model
     AND usmd_objstat = 'A'.
  "
  IF sy-subrc NE 0.
    " 레코드 검색 실패
    MESSAGE s000(oo) WITH 'Data not found.' DISPLAY LIKE 'E'.
    " 작업 종료
    STOP.
  ENDIF.

*--------------------------------------
  " 모델별 작업
  LOOP AT lt_model INTO lv_model.
    "
    WRITE:/ ' *** ' , lv_model COLOR 7, ' *** '.

    "*----------------------------
    " 모델 정보로 활성된 테이블 정보 검색
    CALL METHOD cl_usmd_adapter_provider=>get_model_generation_adapter
      EXPORTING
        i_usmd_model         = lv_model
      IMPORTING
        eo_model_gen_adapter = lo_model_gen_adapter
        et_message           = lt_message.

    CLEAR lv_error.
    "
    LOOP AT lt_message TRANSPORTING NO FIELDS WHERE msgty CA 'AEX'.
      "*----------------------------
      " 오륲 메세지 처리
      MESSAGE ID ls_message-msgid TYPE 'S' NUMBER ls_message-msgno DISPLAY LIKE ls_message-msgty
        WITH ls_message-msgv1 ls_message-msgv2 ls_message-msgv3 ls_message-msgv4.
      " 오류 발생
      lv_error = abap_true.
    ENDLOOP.

    "*----------------------------
    " 오류 없을시 작업 진행
    CHECK lv_error IS INITIAL.

    "*----------------------------
    " 활성 테이블 정보 검색
    CALL METHOD lo_model_gen_adapter->get_generated_objects
      EXPORTING
        if_mdf_hry_tab   = abap_false
      IMPORTING
        et_message       = lt_message
        et_log_phys_name = lt_log_phys_name.    " 활성 테이블 정보

    "*----------------------------
    "
    LOOP AT lt_log_phys_name INTO ls_log_phys_name.

      CASE ls_log_phys_name-sub_kind.
        WHEN usmd1_cs_tabl_kind-check.
          "
          lv_entity    = ls_log_phys_name-entity.
          lv_table     = ls_log_phys_name-phys_name.
          lv_key_field = 'USMDK' && lv_model && lv_entity.

          "
          WRITE:/ '*', lv_entity, lv_table.

          TRY .
              "*----------------------------
              " 테이블 키 밸류 검색
              SELECT (lv_key_field)
                FROM (lv_table)
                INTO TABLE @lt_key_value.
            CATCH cx_sy_dynamic_osql_semantics.
              CONTINUE.
          ENDTRY.

          "*----------------------------
          " 키 중복 제거
          SORT lt_key_value.
          DELETE ADJACENT DUPLICATES FROM lt_key_value.

          "*----------------------------
          " 키 밸류별 작업
          LOOP AT lt_key_value INTO lv_key_value.
            "
            CLEAR: lv_flag_del.
            "
            lv_usmd_value = lv_key_value.

            " 키에 매핑된 Change Request 정보 검색
            SELECT usmd_crequest
              INTO TABLE lt_cr
              FROM usmd1213
             WHERE usmd_entity     = lv_entity
               AND usmd_entity_obj = lv_entity
               AND usmd_value      = lv_usmd_value.
            IF sy-subrc <> 0.
              " 삭제 대상 설정
              lv_flag_del = abap_true.
            ENDIF.

            " Change Request 별 상태 검색
            LOOP AT lt_cr INTO lv_cr.
              SELECT SINGLE mandt
                INTO sy-mandt
                FROM usmd120c
               WHERE usmd_crequest = lv_cr
                 AND usmd_creq_status NOT IN (usmd0_cs_crequest_status-finally_approved,  " 05: 승인완료
                                              usmd0_cs_crequest_status-finally_rejected). " 06: 반려완료.
              IF sy-subrc <> 0.
                " 삭제 대상 설정
                lv_flag_del = abap_true.
                " 루프 종료
                EXIT.
              ENDIF.
            ENDLOOP. " LOOP AT lt_cr INTO lv_cr.

            "*----------------------------
            " 삭제 대상인 경우
            IF lv_flag_del EQ abap_true.
              "
              lv_where = |{ lv_key_field } = lv_key_value|.

*              lv_table = lt_log_phys_name[ entity   = lv_entity
*                                           sub_kind = usmd1_cs_tabl_kind-map ]-phys_name.
              READ TABLE lt_log_phys_name INTO ls_log_phys_name
               WITH KEY entity = lv_entity sub_kind = usmd1_cs_tabl_kind-map.
              lv_table = ls_log_phys_name-phys_name.
              "
              CREATE DATA lr_data TYPE (lv_table).
              ASSIGN lr_data->* TO <ls_data>.
              "
              lv_key_json = lv_usmd_value.
              SELECT SINGLE * INTO <ls_data>
                FROM (lv_table)
               WHERE (lv_where).
              "
              lv_key_json = /ui2/cl_json=>serialize( <ls_data> ).
              "
              WRITE:/ lv_key_json.

              "*----------------------------
              " 테이블별 레코드 삭제
              " 엔티티별 매핑 테이블이 아닌 테이블에 대해 작업
              LOOP AT lt_log_phys_name INTO ls_log_phys_name
                                      WHERE kind     = 'TABL'
                                        AND entity   = lv_entity
                                        AND sub_kind <> usmd1_cs_tabl_kind-map.
                "*----------------------------
                " 테이블 아이디 설정
                lv_table = ls_log_phys_name-phys_name.
                "*----------------------------
                " 테이블 레코드 삭제 처리
                DELETE FROM (lv_table) WHERE (lv_where).
              ENDLOOP.
            ENDIF.
          ENDLOOP. " LOOP AT lt_key_value INTO lv_key_value.


        WHEN usmd1_cs_tabl_kind-map.
          "
          lv_entity    = ls_log_phys_name-entity.
          lv_table     = ls_log_phys_name-phys_name.
          lv_key_field = 'USMDK' && lv_model && lv_entity.

          "
          WRITE:/ '*', lv_entity, lv_table, 'USMD1213'.

          TRY .
              "*----------------------------
              " 테이블 키 밸류 검색
*              lv_select = |'I' AS SIGN, 'EQ' AS OPTION, { lv_key_field } AS LOW|.
              lv_select = lv_key_field.
              SELECT (lv_select)
                FROM (lv_table)
*                INTO TABLE @lt_range_key_value.
                INTO TABLE @lt_key_value.
              SORT lt_key_value.
            CATCH cx_sy_dynamic_osql_semantics.
              CONTINUE.
          ENDTRY.

          " 키에 매핑 안된 Change Request 정보 검색
          SELECT *
            INTO TABLE lt_usmd1213
            FROM usmd1213
           WHERE usmd_entity     = lv_entity
             AND usmd_entity_obj = lv_entity.
*             AND usmd_value      NOT IN lt_range_key_value.

          LOOP AT lt_usmd1213 INTO ls_usmd1213.
            READ TABLE lt_key_value TRANSPORTING NO FIELDS WITH KEY table_line = ls_usmd1213-usmd_value BINARY SEARCH.
            IF sy-subrc EQ 0.
              DELETE lt_usmd1213.
            ELSE.
              lv_key_json = /ui2/cl_json=>serialize( ls_usmd1213 ).
              WRITE:/ lv_key_json.
            ENDIF.
          ENDLOOP.

          DELETE usmd1213 FROM TABLE lt_usmd1213.

        WHEN OTHERS.
      ENDCASE.

    ENDLOOP. " LOOP AT lt_log_phys_name INTO ls_log_phys_name

  ENDLOOP. " LOOP AT lt_model INTO lv_model.

*--------------------------------------
  " 커밋
  COMMIT WORK.

abap2json

Derby — Fri, 9 Jun 2023 11:33:03 +0900

취미로 개발중인 프로그램...

https://github.com/boy0korea/abap2json

GitHub - boy0korea/abap2json: abap2json is convertor to export abap table data to json format

abap2json is convertor to export abap table data to json format - GitHub - boy0korea/abap2json: abap2json is convertor to export abap table data to json format

github.com

abap2xlsx 를 패러디 하여 abap2json 으로 이름을 지었습니다.

테이블 내용을 json 포맷으로 저장합니다.

개발서버-품질서버-운영서버 간에 데이터를 복사할때도 사용할 수 있습니다.

(서버간 데이터 복사는 RFC 펑션으로 전달되며 전송에 json 포맷이 사용됩니다)

파일 생성 예

프로그램 ZABAP2JSON

Import ZIP

가져오기 (*.json.zip)

Comapre ZIP

비교 (*.json.zip)

Export Table

내보내기 테이블 단위 TABLE.datetime.json.zip

Export Package

내보내기 패키지 단위 *.json.zip

Comapre Table

서버간 테이블 내용 비교

Copy Table

서버간 테이블 내용 복사

search help exit 총정리

Derby — Tue, 25 Apr 2023 15:57:28 +0900

DDIC 서치 헬프 만드는 방법에는 3가지가 있습니다.

Selection Method 에 테이블 입력
Search Help Exit 에 펑션 입력
Selection Method와 Search Help Exit 둘다 입력

테이블을 입력해서 만드는건 가장 기초적인 작성법이니 쉽게 아실테고 Exit 펑션을 입력하여 만드는 방법이 난이도가 상당히 있습니다.

개발을 시작하는 방법은 우선 펑션모듈 F4IF_SHLP_EXIT_EXAMPLE 을 복사하여 펑션모듈을 하나 만듭니다.

이 펑션에는 파라미터 4개가 있습니다. 이중 CALLCONTROL 과 SHLP 이 두 파라미터를 이용합니다.

exit 펑션은 CALLCONTROL-STEP 값이 변경되면서 여러번 호출 됩니다.

F4IF_SHLP_EXIT_EXAMPLE에 각 CALLCONTROL-STEP 에 따른 설명이 들어 있으니 참고 하시기 바랍니다.

보통은 SELECT와 DISP 일때만 처리합니다.

SHLP-SELOPT : 검색조건 range. SELECT step 에서 변경 하면 화면에 반영됩니다. DISP step 에서는 변경 못합니다.

SHLP-FIELDDESCR : 필드 명세. 예를 들어 필드 헤더 텍스트는 SCRTEXT_* 에 값을 변경하면 됩니다.

SHLP-FIELDPROP: 필드 속성. 서치헬프 파라미터 부분에 설정한 내용을 변경 할 수 있습니다. 예를 들어 표시 순서는 SHLPLISPOS 에 값을 변경하면 됩니다.

CALLCONTROL-STEP : step 조건. 예를 들어 값을 EXIT로 변경하면 서치헬프가 종료 됩니다. 자동으로 값을 리턴하는 방법도 있는데 RETURN 으로 변경하고 F4UT_PARAMETER_RESULTS_PUT 펑션을 이용하여 결과 값을 넘겨주면 됩니다.

CALLCONTROL-SORTOFF : 'X'로 값을 주면 자동 정렬 끄기. 내맘대로 정렬 할 수 있습니다.

CALLCONTROL-MAXRECORDS : 최대 결과 수

CALLCONTROL-MAXEXCEED : 검색 결과가 최대 결과 수 초과 여부

CALLCONTROL-TOP_SHLP : Collective search help 의 경우 지금 선택된 Elementary search help

복잡한 코딩 예는 아래 프로젝트를 참고하시기 바랍니다.

https://github.com/boy0korea/ALL_ROUND_SEARCH_HELP

GitHub - boy0korea/ALL_ROUND_SEARCH_HELP: All Round Search Help

All Round Search Help. Contribute to boy0korea/ALL_ROUND_SEARCH_HELP development by creating an account on GitHub.

github.com

간단한 예제 코드는 이렇습니다.

FUNCTION zmdp_hr_exit_usr_tel.
*"--------------------------------------------------------------------
*"*"Local Interface:
*"  TABLES
*"      SHLP_TAB TYPE  SHLP_DESCT
*"      RECORD_TAB STRUCTURE  SEAHLPRES
*"  CHANGING
*"     VALUE(SHLP) TYPE  SHLP_DESCR
*"     VALUE(CALLCONTROL) LIKE  DDSHF4CTRL STRUCTURE  DDSHF4CTRL
*"--------------------------------------------------------------------
  TYPES:
    BEGIN OF lty_stru_list,
*   add fields for the selection list here
      tel TYPE zmdpt_m_usr-tel,
    END OF lty_stru_list.
  DATA: lt_select_list TYPE STANDARD TABLE OF lty_stru_list,
        ls_select_list LIKE LINE OF lt_select_list,
        ls_selopt      TYPE ddshselopt,
        lv_keydate     TYPE datum,
        lt_range_tel   TYPE RANGE OF zmdpt_m_usr-tel,
        ls_range_tel   LIKE LINE OF lt_range_tel.

  CHECK: callcontrol-step EQ 'SELECT'.

  LOOP AT shlp-selopt INTO ls_selopt.
    CASE ls_selopt-shlpfield.
      WHEN 'TEL'.
        MOVE-CORRESPONDING ls_selopt TO ls_range_tel.
        REPLACE ALL OCCURRENCES OF REGEX '[^[:digit:]*+]' IN ls_range_tel-low WITH ''.
        REPLACE ALL OCCURRENCES OF REGEX '[^[:digit:]*+]' IN ls_range_tel-high WITH ''.
        APPEND ls_range_tel TO lt_range_tel.
      WHEN 'KEYDATE'.
        lv_keydate = ls_selopt-low.
    ENDCASE.
  ENDLOOP.

  IF lv_keydate IS INITIAL.
    lv_keydate = sy-datum.
    CLEAR: ls_selopt.
    ls_selopt-shlpfield = 'KEYDATE'.
    ls_selopt-sign = 'I'.
    ls_selopt-option = 'EQ'.
    ls_selopt-low = lv_keydate.
    APPEND ls_selopt TO shlp-selopt.
  ENDIF.


  SELECT DISTINCT tel
    INTO TABLE lt_select_list
    FROM zmdpt_m_usr
    WHERE tel_mc IN lt_range_tel
      AND begda <= lv_keydate
      AND endda >= lv_keydate.
  CHECK: lt_select_list IS NOT INITIAL.

  callcontrol-maxexceed = abap_false.
  IF callcontrol-maxrecords IS NOT INITIAL AND
     lines( lt_select_list ) > callcontrol-maxrecords.
    DELETE lt_select_list FROM callcontrol-maxrecords + 1.
    callcontrol-maxexceed = abap_true.
  ENDIF.

* map
  CALL FUNCTION 'F4UT_RESULTS_MAP'
    TABLES
      shlp_tab    = shlp_tab
      record_tab  = record_tab
      source_tab  = lt_select_list
    CHANGING
      shlp        = shlp
      callcontrol = callcontrol.

  callcontrol-step = 'DISP'.


ENDFUNCTION.

엘프바(elfbar) 분해

Derby — Mon, 17 Apr 2023 13:59:14 +0900

분해하는데 도구는 필요없고 쌔게 잡아댕기면 됩니다.
니코틴 먹은 스펀지와 배터리와 충전모듈 그리고 코일이 있네요.
배터리는 3.7v 650mAh 라고 써있습니다.

FUNCTION ZADD_1_ALPHANUM

Derby — Tue, 20 Dec 2022 15:19:56 +0900

숫자와 영문자 순번 증가

10+26개 = 36진법

FUNCTION ZADD_1_ALPHANUM.
*"----------------------------------------------------------------------
*"*"Local Interface:
*"  IMPORTING
*"     REFERENCE(IV_SKIP_CHAR) TYPE  CLIKE OPTIONAL
*"     REFERENCE(IV_OFFSET) TYPE  I DEFAULT -1
*"  CHANGING
*"     REFERENCE(CV_DATA) TYPE  CLIKE
*"----------------------------------------------------------------------
* 이 구현은 ECATT_INCREASE_ALPHANUM_ID 를 참고 하였습니다.
* overflow가 발생하면 000...0 으로 다시 돌아갑니다.
* 자리수가 자동으로 늘어나면서 앞에 1이 붙지는 않습니다.

  CONSTANTS: lc_trans TYPE char72 VALUE '0112233445566778899AABBCCDDEEFFGGHHIIJJKKLLMMNNOOPPQQRRSSTTUUVVWWXXYYZZ0'.
  DATA: lv_c      TYPE char1,
        lv_offset TYPE i.

  IF iv_offset < 0.

    lv_offset = strlen( cv_data ) - 1.    " 마지막 글자 위치.
    CALL FUNCTION 'ZADD_1_ALPHANUM'
      EXPORTING
        iv_skip_char = iv_skip_char
        iv_offset    = lv_offset
      CHANGING
        cv_data      = cv_data.

  ELSE.

    lv_c = cv_data+iv_offset(1).
    TRANSLATE cv_data+iv_offset(1) USING lc_trans.

    IF cv_data+iv_offset(1) EQ '0'.
*   자리수 올림은 재귀 호출로 처리한다.
      lv_offset = iv_offset - 1.    " 앞 글자 위치.
      IF lv_offset >= 0.
        CALL FUNCTION 'ZADD_1_ALPHANUM'
          EXPORTING
            iv_skip_char = iv_skip_char
            iv_offset    = lv_offset
          CHANGING
            cv_data      = cv_data.
      ENDIF.
    ENDIF.

    IF iv_skip_char IS NOT INITIAL AND
       cv_data+iv_offset(1) CA iv_skip_char.
      CALL FUNCTION 'ZADD_1_ALPHANUM'
        EXPORTING
          iv_skip_char = iv_skip_char
          iv_offset    = iv_offset
        CHANGING
          cv_data      = cv_data.
    ENDIF.
  ENDIF.

ENDFUNCTION.

HTML_FRAGMENT 를 이용한 JavaScript 넣기 꼼수

Derby — Thu, 2 Jun 2022 17:40:36 +0900

웹딘프로 layout에 HTML_FRAGMENT를 하나 그려줍니다.

WDDOMODIFYVIEW 메소드에서

IF first_time EQ abap_true. 으로 한번만 실행되도록 하고

HTML_FRAGMENT 엘리먼트의 html 속성에 HTML tag를 하나 넣겠습니다.

<img src="/sap/public/bc/ur/nw5/1x1.gif" style="display: none;" onload="alert('script test');" />

ABAP 코드는 이렇습니다.

CAST cl_wd_html_fragment( io_view->get_element( 'HTML_FRAGMENT' ) )->set_html(
  `<img src="/sap/public/bc/ur/nw5/1x1.gif" style="display: none;" onload="alert('script test');" />`
).

내용을 설명드리겠습니다.

IMG tag를 이용해서 onload 시점에 실행할 JavaScript를 넣으면 됩니다. 예를 들어 아래 테스트 코드를 넣어 봤습니다.

alert('script test');

IMG의 onload가 실행되는 시점은 웹브라우저가 화면을 그리고 src 속성의 파일을 읽어와서야 실행됩니다. 매우 나중에 실행되는 타이밍입니다.

좀 더 복잡한 스크립트가 들어간 예제를 보여드리겠습니다.

파일 업로드 팝업인데 팝업이 뜨면 웹딘프로의 파일업로드 엘리먼트를 클릭하지 않아도 자동으로 클릭해서 파일 선택 창이 나오고 파일을 선택하면 자동으로 팝업의 OK 버튼을 눌러 닫힙니다.

CAST cl_wd_html_fragment( io_view->get_element( 'HTML_FRAGMENT' ) )->set_html(
  `<img src="/sap/public/bc/ur/nw5/1x1.gif" style="display: none;" ` &&
  `onload="` &&
  `var el = this;` &&
  `while( !el.classList.contains('lsPopupWindow') ) {` &&                 " popup div
  `  el = el.parentElement;` &&
  `}` &&
  `var file = el.querySelector('input[type=file]');` &&                   " file input box
  `var ok = el.querySelector('.urPWFooterBottomLine .lsButton');` &&      " ok button
  `file.oninput = function() { UCF_JsUtil.delayedCall( 200, ok, 'click' ); };` &&
  `file.click();` &&
  `" />`
).

IMG tag를 이용한 onload에 스크립트 넣기 방식은 동일합니다. JavaScript만 가져와서 보겠습니다.

var el = this;
while( !el.classList.contains('lsPopupWindow') ) {
  el = el.parentElement;
}
var file = el.querySelector('input[type=file]');
var ok = el.querySelector('.urPWFooterBottomLine .lsButton');
file.oninput = function() { UCF_JsUtil.delayedCall( 200, ok, 'click' ); };
file.click();

처음 4줄은 el 변수에 lsPopupWindow 이라는 class 속성을 가진 엘리먼트를 찾습니다. (웹딘프로 팝업의 태두리입니다)

5번째줄은 file 변수에 input tag의 type 속성이 file인 엘리먼트를 찾습니다. (웹딘프로 FILE_UPLOAD 엘리먼트에 해당합니다)

6번째줄은 ok 변수에 urPWFooterBottomLine 이라는 class 속성을 가진 엘리먼트 아래에 lsButton 이라는 class 속성을 가진 엘리먼트를 찾습니다. (웹딘프로 팝업의 아래쪽 OK 버튼에 해당합니다)

7번째줄은 파일 업로드 엘리먼트에 oninput 시점에 200ms 딜레이를 주고나서 OK 버튼을 click 하라는 뜻입니다. (이것은 파일 선택후 자동으로 팝업을 닫기 위한 코드 입니다)

8번째줄은 파일 업로드 엘리먼트를 click 하라는 뜻입니다. (파일 선택 창이 열립니다)

이 코드는 아래 프로젝트에 포함되어 있습니다.

https://github.com/boy0korea/ABAP2XLSX_HELPER

GitHub - boy0korea/ABAP2XLSX_HELPER: abap2xlsx helper

abap2xlsx helper. Contribute to boy0korea/ABAP2XLSX_HELPER development by creating an account on GitHub.

github.com

/SCMTMS/CL_TOR_HELPER_COMMON=>GET_TOR_DATA 와 Secondary Key 활용

Derby — Thu, 2 Jun 2022 15:41:58 +0900

사용법은 보통 이런식으로...

/scmtms/cl_tor_helper_common=>get_tor_data(
  EXPORTING
    it_root_key      = lt_root_key
  IMPORTING
    et_all_items     = lt_all_items
).

실행되는건 아래 코드와 같은 내용입니다.

DATA(lo_srv_mgr) = /bobf/cl_tra_serv_mgr_factory=>get_service_manager( /scmtms/if_tor_c=>sc_bo_key ).
lo_srv_mgr->retrieve_by_association(
  EXPORTING
    iv_node_key       = /scmtms/if_tor_c=>sc_node-root
    it_key            = lt_root_key
    iv_association    = /scmtms/if_tor_c=>sc_association-root-item_tr
    iv_fill_data      = abap_true
  IMPORTING
    et_data           = lt_all_items
).

실용적인 코드 템플릿 >

DATA:
LT_ROOT_KEY TYPE /BOBF/T_FRW_KEY,
LT_ROOT	TYPE /SCMTMS/T_TOR_ROOT_K,
LT_ALL_ITEMS TYPE /SCMTMS/T_TOR_ITEM_TR_K,
LT_STOP	TYPE /SCMTMS/T_TOR_STOP_K,
LT_STOP_SUCC_ALL TYPE /SCMTMS/T_TOR_STOP_SUCC_K,
LT_DOC_REFERENCE TYPE /SCMTMS/T_TOR_DOCREF_K,
LT_EXEC TYPE /SCMTMS/T_TOR_EXEC_K,
LT_PARTY TYPE /SCMTMS/T_TOR_PARTY_K,

FIELD-SYMBOLS:
<LS_ROOT> TYPE /SCMTMS/S_TOR_ROOT_K,
<LS_ITEM> TYPE /SCMTMS/S_TOR_ITEM_TR_K,
<LS_STOP> TYPE /SCMTMS/S_TOR_STOP_K,
<LS_STOP_SUCC> TYPE /SCMTMS/S_TOR_STOP_SUCC_K,
<LS_DOC_REFERENCE> TYPE /SCMTMS/S_TOR_DOCREF_K,
<LS_EXEC> TYPE /SCMTMS/S_TOR_EXEC_K,
<LS_PARTY> TYPE /SCMTMS/S_TOR_PARTY_K,

" Invalidate cache
/bobf/cl_tra_trans_mgr_factory=>get_transaction_manager( )->cleanup( ).

" Get TOR data
/scmtms/cl_tor_helper_common=>get_tor_data(
  EXPORTING
    it_root_key      = lt_root_key
  IMPORTING
    et_root          = lt_root
    et_all_items     = lt_all_items
    et_stop          = lt_stop
    et_stop_succ_all = lt_stop_succ_all
    et_doc_reference = lt_doc_reference
    et_exec          = lt_exec
    et_party         = lt_party
).

/SCMTMS/T_TOR_ITEM_TR_K에 Secondary Key 가 여러개 있습니다.
Internal Table 의 Secondary Key 는 마치 DB Index 와 비슷한 역할을 하여 검색 속도를 빠르게 해줍니다.
차이점은 Secondary Key 가 여러개 있어도 Insert 속도에 영향을 주지 않습니다.
Secondary Key 의 Indexing 생성 시기는 최초 사용시 입니다. 사용하지 않는 Secondary Key 는 Indexing 하지 않습니다.


" ITEM_CAT = 'AVR' (차량)
READ TABLE lt_all_items ASSIGNING <ls_item> WITH KEY root_itmcat COMPONENTS root_key = <ls_root>-key item_cat = 'AVR'.

" ITEM_CAT = 'DRI' (드라이버)
READ TABLE lt_all_items ASSIGNING <ls_item> WITH KEY root_itmcat COMPONENTS root_key = <ls_root>-key item_cat = 'DRI'.

" ITEM_CAT = 'PRD' (제품)
LOOP AT lt_all_items ASSIGNING <ls_item> USING KEY root_itmcat WHERE <ls_root>-key item_cat = 'PRD'.

이렇게 Secondary Key 를 사용할때는 READ TABLE ... WITH KEY , LOOP AT ... USING KEY 구문을 쓰면 됩니다.

Item 노드 뿐만이 아니라 다른 노드에 대한 인터널 테이블도 모두 Secondary Key가 많이 있으니 찾아보고 활용해 보세요.

Search UIBB에 relative date(예: Today)를 기본값으로 넣는 방법

Derby — Thu, 2 Jun 2022 14:49:54 +0900

아래 예는 Yesterday, Today, Tommorow 를 입력하는 코드 입니다.

ev_search_criteria_changed = abap_true.
CLEAR: ls_fpm_search_criteria.
ls_fpm_search_criteria-search_attribute = 'DATE_FIELDNAME'.
ls_fpm_search_criteria-sign = if_fpm_guibb_search=>gc_sign-include_search_criteria.
ls_fpm_search_criteria-operator = if_fpm_guibb_search=>gc_operators-is.
ls_fpm_search_criteria-low = 'FPM_RD_FPM_DATE_YESTERDAY'.
APPEND ls_fpm_search_criteria TO ct_fpm_search_criteria.
ls_fpm_search_criteria-operator = if_fpm_guibb_search=>gc_operators-is.
ls_fpm_search_criteria-low = 'FPM_RD_FPM_DATE_TODAY'.
APPEND ls_fpm_search_criteria TO ct_fpm_search_criteria.
ls_fpm_search_criteria-operator = if_fpm_guibb_search=>gc_operators-is.
ls_fpm_search_criteria-low = 'FPM_RD_FPM_DATE_TOMORROW'.
APPEND ls_fpm_search_criteria TO ct_fpm_search_criteria.

FPM_RD_FPM_DATE_TODAY 라는 특별한 값을 주면 Today로 나타 납니다.

FPM_RD_ 와 FPM_DATE_TODAY 를 붙인 값입니다.

CL_FPM_SEARCH_UIBB_SELOPT->SET_SO_REL_DATES 에서 상수 GC_PREFIX_REL_DATE = 'FPM_RD_'

CL_FPM_DATE_DEFAULT_TOKEN_PROV->IF_FPM_TOKEN_PROVIDER~RESOLVE_TOKEN 에서 상수 GC_TOKEN_TODAY = 'FPM_DATE_TODAY'

relative date의 장점은 variant로 저장한 것을 불러 오더라도 저장할때의 고정된 날짜가 아니라 항상 날짜를 다시 계산 한다는 점입니다.

알리익스프레스 X 에이씨티앤코아 X 스마트택배 앱으로 배송 조회 알림

Derby — Fri, 20 May 2022 19:04:49 +0900

스마트택배 앱의 해외배송추적 기능이 많이 좋아졌습니다.

알리익스프레스 에서 구매한 물건을 배송 조회 등록하는 방법을 알려드리겠습니다.

알리익스프레스 앱에서 배송 조회를 해서 송장번호를 복사합니다.

N으로 시작하는거(saver shipping) 는 안되구요. 6이나 7로 시작하는 번호 됩니다.

스마트택배 앱에 입력하도록 하죠. + 버튼 누르고 직접 등록 선택합니다.

택배사를 선택하세요.

예전에는 국내택배-우체국 으로 등록했었는데....
이제 해외택배-에이씨티앤코아물류 선택하여 더 자세한 배송 정보를 받아볼 수 있습니다.
정렬이나 검색이 안되어서 좀 불편한데요. 중간쯤 내리면 있습니다.

통관 정보 추가 체크 해주시구요.
등록하면 됩니다.

배송 상세화면에서 택배사에서 보기 누르면 아래 처럼 아주 자세한 정보를 추가로 확인할 수 있어요.

/SCMTMS/CL_UI_NAVIGATION=>START_NAVIGATION

Derby — Thu, 19 May 2022 15:56:19 +0900

메소드 파라미터가 매우 많습니다.

필수는 없고 모든 파라미터가 선택사항이라 필요에 따라 조합하여 사용합니다.

입력 파라미터 설명
유형1: BO	IV_BO_KEY	BO Key
	IV_BO_NAME	BO Name. 입력시 내부에서 BO Key로 변환
	IV_BO_CATEGORY	BO Category. TOR,TRQ,FA 의 경우 필요함. 생략시 자동 찾음.
	IV_CHANGE_MODE	Mode (빈값: display, C: create, U: change)
	IV_KEY	BO 데이터 Key
	IV_SRC_INST_KEY	create mode 에서 원본 데이터 키 지정
	IV_TCM_TEMPLATE	scale,rate,tccs 에서 템플릿 사용시
	IV_REF_CREATE_MODE	create mode 에서 reference mode 지정
	IT_BO_DATA	Shared Memory에 write
	IV_SKIP_INITIAL_SCREEN	Initial Screen 건너뜀
유형2: FPM	IV_TARGET_APPL	FPM Appl.
유형2: FPM	IV_CONFIGURATIONID	FPM Config.
유형3: URL	IV_EXTERNAL_URL	External URL
공통	IT_PARAMETERS	추가 파라미터
공통	IV_INPLACE_NAVIGATION	빈값: 새창으로, X: Inplace

사용 예

예제1: TOR Key로 조회

/scmtms/cl_ui_navigation=>start_navigation(
  EXPORTING
    iv_bo_key      = /scmtms/if_tor_c=>sc_bo_key
    iv_bo_category = /scmtms/if_tor_const=>sc_tor_category-freight_unit
    iv_key         = lv_tor_key
).

예제2: TOR ID로 변경

/scmtms/cl_ui_navigation=>start_navigation(
  EXPORTING
    iv_bo_key      = /scmtms/if_tor_c=>sc_bo_key
    iv_bo_category = /scmtms/if_tor_const=>sc_tor_category-freight_unit
    iv_key         = /scmtms/cl_tor_helper_root=>return_key_for_torid( lv_tor_id )
    iv_change_mode = /bofu/if_fbi_runtime_c=>sc_change_modes-change
).

예제3: TRQ 생성

/scmtms/cl_ui_navigation=>start_navigation(
  EXPORTING
    iv_bo_key          = /scmtms/if_trq_c=>sc_bo_key
    iv_bo_category     = /scmtms/if_trq_const=>c_trq_category-forwarding_order
    iv_change_mode     = /bofu/if_fbi_runtime_c=>sc_change_modes-create
    iv_src_inst_key    = lv_fwq_key
    iv_ref_create_mode = /scmtms/if_ui_trq_c=>sc_action_param-ref_create_mode-fwo_from_fwq
).

예제4: schedule Key로 조회

/scmtms/cl_ui_navigation=>start_navigation(
  EXPORTING
    iv_bo_key = /scmtms/if_fo_schedule_c=>sc_bo_key
    iv_key    = ls_item-sched_key
).

예제5: location ID로 조회

/scmtms/cl_ui_navigation=>start_navigation(
  EXPORTING
    iv_bo_key     = /scmtms/if_location_c=>sc_bo_key
    it_parameters = VALUE #(
      ( key = 'LOCATION' value = ls_stop-log_locid )
    )
).

예제6: resource ID로 조회

/scmtms/cl_ui_navigation=>start_navigation(
  EXPORTING
    iv_bo_key     = /scmtms/if_resource_c=>sc_bo_key
    it_parameters = VALUE #(
      ( key = 'RESOURCE' value = ls_item-res_id )
    )
).

예제7: product(material) ID로 조회

/scmtms/cl_ui_navigation=>start_navigation(
  EXPORTING
    iv_bo_key     = /scmtms/if_mat_c=>sc_bo_key
    it_parameters = VALUE #(
      ( key = 'PRODUCT' value = ls_item-product_id )
    )
).

예제8: BP ID로 조회

/scmtms/cl_ui_navigation=>start_navigation(
  EXPORTING
    iv_bo_key     = /bofu/if_bupa_constants=>sc_bo_key
    it_parameters = VALUE #(
      ( key = 'PARTNER' value = lv_bp_id )
      ( key = 'ROLE' value = lv_bp_role )
    )
).

예제9: order document 조회

/scmtms/cl_ui_navigation=>start_navigation(
  EXPORTING
    it_parameters = VALUE #(
      ( key = /scmtms/if_ui_cmn_c=>sc_wd_parameter-base_btd_tco
        value = ls_docref-btd_tco )
      ( key = /scmtms/if_ui_cmn_c=>sc_wd_parameter-base_btd_id
        value = ls_docref-btd_id )
    )
).

예제10: 스탠다드 worklist(POWL) 참고

/SCMTMS/CL_UI_ACTION_TOR->HANDLE_ACTION

ABAP TIMESTAMP 총정리

Derby — Mon, 27 Dec 2021 16:33:00 +0900

타임스탬프로 사용되는 타입은 두가지가 있습니다.

TIMESTAMP : 15자리 YYYYMMDDhhmmss

TIMESTAMPL : 21자리 YYYYMMDDhhmmss.ssssss

주로 사용하는 15자리 TIMESTAMP 를 기준으로 설명하겠습니다.

예를 들어 인천 에서 홍콩으로 가는 항공편의 출발시간, 도착시간을 보면서 타임스탬프의 필요성을 이해해 보도록 하게습니다.

	출발시간	도착시간
현지 시간	2022.01.01 09:00:00	2022.01.01 12:00:00
타임존	UTC+9	UTC+8
타임스탬프 (UTC 기준 시간)	2022.01.01 00:00:00	2022.01.01 04:00:00
출발지(UTC+9) 기준 시간	2022.01.01 09:00:00	2022.01.01 13:00:00
도착지(UTC+8) 기준 시간	2022.01.01 08:00:00	2022.01.01 12:00:00

보통 표시할때는 현지 시간 + 타임존 으로 표시를 합니다. 그게 이해하기 쉬우니까요. 인천 9시 출발, 홍콩 12시 도착 입니다.

그럼 비행시간을 계산하려면 어떻게 할까요? 12-9는 3시간 틀렸습니다. 타임존이 다르기 때문이죠.

비행시간을 계산하기 위해서는 출발 도착 둘다 같은 타임존을 가지도록 값을 변환해야 합니다.

위 표에서 UTC 기준, 출발지 기준, 도착지 기준 3가지 모두 비행시간을 계산할때 사용할 수 있습니다.

DB에 저장할때는 어떤값을 저장하는게 효과적일까요?

정답은 타임스탬프(=UTC 기준 시간) 입니다. 다른경우와 다르게 타임존을 저장할 필요가 없기 때문에 더 작은 공간을 차지합니다.

타임존은 출발지와 도착지 각 장소별로 저장하면 됩니다.

이제 ABAP 문법을 알아 보겠습니다.

현재 타임스탬프 가져오는 방법:

GET TIME STAMP FIELD lv_ts.

타임스탬프를 날짜, 시간 두 필드로 변환하는 방법:

CONVERT TIME STAMP lv_ts TIME ZONE sy-zonlo INTO DATE lv_date TIME lv_time.

날짜,시간 두 필드를 타임스탬프로 변환하는 방법:

CONVERT DATE lv_date TIME lv_time INTO TIME STAMP lv_ts TIME ZONE sy-zonlo.

타임스탬프를 글자표현(예: YYYY.MM.DD hh:mm:ss) 으로 변환하는 방법:

|{ lv_ts TIMEZONE = sy-zonlo }|

타임스탬프 관련 유용한 conversion routine 을 소개 합니다.

'TSTLC' : 타임존 sy-zonlo 기준으로 표시합니다. 예를들어 데이터 엘리먼트는 EHFND_TIME_STAMP 가 있습니다.

'TSTPS' : 타임존 UTC 기준으로 표시합니다. 예를들어 데이터 엘리먼트는 BCOS_TSTMP 가 있습니다.

타임존 sy-zonlo 기준으로 표시 할때의 장점:

sy-zonlo는 사용자의 타임존입니다.

각자 티코드 SU3에서 변경 할 수 있습니다.

보통 DB 테이블 마다 들어가는 생성날짜와 생성시간을 sy-datum 과 sy-uzeit 값을 넣어서 기록합니다.

국제화 시대에 맞춰 타임스탬프로 기록하면 시스템 타임존과 다른 타임존을 사용하는 사용자도 편하게 볼수있습니다.

예를들어 타임스탬프 값이 2022.01.01 00:00:00 이라면,

UTC+9 타임존 사용자는 2022.01.01 09:00:00 로 표시되고,

UTC+8 타임존 사용자는 2022.01.01 08:00:00 로 표시됩니다.

다음은 DB 검색시 타임스탬프로 기록된 필드를 검색하는 방법 입니다.

FUNCTION zconvert_range_date2ts.
*"----------------------------------------------------------------------
*"*"Local Interface:
*"  IMPORTING
*"     REFERENCE(IT_RANGE_DATE) TYPE  RANGE_DATE_T
*"  EXPORTING
*"     REFERENCE(ET_RANGE_TS) TYPE  CRMT_BUS_TIMESTAMP_RANGE_T
*"----------------------------------------------------------------------
  CONSTANTS: lc_time_end TYPE uzeit VALUE '235959'.
  DATA: ls_range_date TYPE range_date,
        ls_range_ts   TYPE crmt_bus_timestamp_range.

  CLEAR: et_range_ts.

  LOOP AT it_range_date INTO ls_range_date.
    CLEAR: ls_range_ts.
    ls_range_ts-sign = ls_range_date-sign.
    ls_range_ts-option = ls_range_date-option.

    CASE ls_range_date-option.
      WHEN 'EQ'.
        ls_range_ts-option = 'BT'.
        CONVERT DATE ls_range_date-low INTO TIME STAMP ls_range_ts-low TIME ZONE sy-zonlo.
        CONVERT DATE ls_range_date-low TIME lc_time_end INTO TIME STAMP ls_range_ts-high TIME ZONE sy-zonlo.
      WHEN 'NE'.
        ls_range_ts-option = 'NB'.
        CONVERT DATE ls_range_date-low INTO TIME STAMP ls_range_ts-low TIME ZONE sy-zonlo.
        CONVERT DATE ls_range_date-low TIME lc_time_end INTO TIME STAMP ls_range_ts-high TIME ZONE sy-zonlo.
      WHEN 'BT'
        OR 'NB'.
        CONVERT DATE ls_range_date-low INTO TIME STAMP ls_range_ts-low TIME ZONE sy-zonlo.
        CONVERT DATE ls_range_date-high TIME lc_time_end INTO TIME STAMP ls_range_ts-high TIME ZONE sy-zonlo.
      WHEN 'GE'.
        CONVERT DATE ls_range_date-low INTO TIME STAMP ls_range_ts-low TIME ZONE sy-zonlo.
      WHEN 'GT'.
        CONVERT DATE ls_range_date-low TIME lc_time_end INTO TIME STAMP ls_range_ts-low TIME ZONE sy-zonlo.
      WHEN 'LE'.
        CONVERT DATE ls_range_date-low TIME lc_time_end INTO TIME STAMP ls_range_ts-low TIME ZONE sy-zonlo.
      WHEN 'LT'.
        CONVERT DATE ls_range_date-low INTO TIME STAMP ls_range_ts-low TIME ZONE sy-zonlo.
      WHEN OTHERS.
        CONTINUE.
    ENDCASE.

    APPEND ls_range_ts TO et_range_ts.
  ENDLOOP.

ENDFUNCTION.

ZCL_MDP_READ_HELPER

Derby — Wed, 15 Dec 2021 14:08:52 +0900

MDG read helper

for BP model

for MM model

코드:

CLASS zcl_mdp_read_helper DEFINITION
  PUBLIC
  CREATE PUBLIC .

  PUBLIC SECTION.

    TYPES ts_bp_key TYPE /mdgbp/_s_bp_ky_bp_header .
    TYPES:
      tt_bp_key TYPE SORTED TABLE OF /mdgbp/_s_bp_ky_bp_header WITH NON-UNIQUE KEY bp_header .
    TYPES ts_bp_bp_header TYPE mdg_bs_bp_bp_header .
    TYPES:
      tt_bp_bp_header TYPE SORTED TABLE OF mdg_bs_bp_bp_header WITH NON-UNIQUE KEY bp_header .
    TYPES ts_bp_ad_email TYPE mdg_bs_bp_ad_email .
    TYPES:
      tt_bp_ad_email TYPE SORTED TABLE OF mdg_bs_bp_ad_email WITH NON-UNIQUE KEY bp_header addrno ad_consno .
    TYPES ts_bp_ad_fax TYPE mdg_bs_bp_ad_fax .
    TYPES:
      tt_bp_ad_fax TYPE SORTED TABLE OF mdg_bs_bp_ad_fax WITH NON-UNIQUE KEY bp_header addrno ad_consno .
    TYPES ts_bp_ad_name_o TYPE mdg_bs_bp_ad_name_o .
    TYPES:
      tt_bp_ad_name_o TYPE SORTED TABLE OF mdg_bs_bp_ad_name_o WITH NON-UNIQUE KEY bp_header addrno ad_nation .
    TYPES ts_bp_ad_name_p TYPE mdg_bs_bp_ad_name_p .
    TYPES:
      tt_bp_ad_name_p TYPE SORTED TABLE OF mdg_bs_bp_ad_name_p WITH NON-UNIQUE KEY bp_header addrno ad_nation .
    TYPES ts_bp_ad_postal TYPE mdg_bs_bp_ad_postal .
    TYPES:
      tt_bp_ad_postal TYPE SORTED TABLE OF mdg_bs_bp_ad_postal WITH NON-UNIQUE KEY bp_header addrno ad_nation .
    TYPES ts_bp_ad_tel TYPE mdg_bs_bp_ad_tel .
    TYPES:
      tt_bp_ad_tel TYPE SORTED TABLE OF mdg_bs_bp_ad_tel WITH NON-UNIQUE KEY bp_header addrno ad_consno .
    TYPES ts_bp_ad_url TYPE mdg_bs_bp_ad_url .
    TYPES:
      tt_bp_ad_url TYPE SORTED TABLE OF mdg_bs_bp_ad_url WITH NON-UNIQUE KEY bp_header addrno ad_consno .
    TYPES ts_bp_address TYPE mdg_bs_bp_address .
    TYPES:
      tt_bp_address TYPE SORTED TABLE OF mdg_bs_bp_address WITH NON-UNIQUE KEY bp_header addrno .
    TYPES ts_bp_bp_addr TYPE mdg_bs_bp_bp_addr .
    TYPES:
      tt_bp_bp_addr TYPE SORTED TABLE OF mdg_bs_bp_bp_addr WITH NON-UNIQUE KEY bp_header addrno .
    TYPES ts_bp_bp_addusg TYPE mdg_bs_bp_bp_addusg .
    TYPES:
      tt_bp_bp_addusg TYPE SORTED TABLE OF mdg_bs_bp_bp_addusg WITH NON-UNIQUE KEY bp_header addrno bp_adrknd .
    TYPES ts_bp_bp_bkdtl TYPE mdg_bs_bp_bp_bkdtl .
    TYPES:
      tt_bp_bp_bkdtl TYPE SORTED TABLE OF mdg_bs_bp_bp_bkdtl WITH NON-UNIQUE KEY bp_header bank_id .
    TYPES ts_bp_bp_ccdtl TYPE mdg_bs_bp_bp_ccdtl .
    TYPES:
      tt_bp_bp_ccdtl TYPE SORTED TABLE OF mdg_bs_bp_bp_ccdtl WITH NON-UNIQUE KEY bp_header card_id .
    TYPES ts_bp_bp_centrl TYPE mdg_bs_bp_bp_centrl .
    TYPES:
      tt_bp_bp_centrl TYPE SORTED TABLE OF mdg_bs_bp_bp_centrl WITH NON-UNIQUE KEY bp_header .
    TYPES ts_bp_bp_idnum TYPE mdg_bs_bp_bp_idnum .
    TYPES:
      tt_bp_bp_idnum TYPE SORTED TABLE OF mdg_bs_bp_bp_idnum WITH NON-UNIQUE KEY bp_header bp_idtype bp_id_num .
    TYPES ts_bp_bp_indstr TYPE mdg_bs_bp_bp_indstr .
    TYPES:
      tt_bp_bp_indstr TYPE SORTED TABLE OF mdg_bs_bp_bp_indstr WITH NON-UNIQUE KEY bp_header bp_indsct bp_indsys .
    TYPES ts_bp_bp_role TYPE mdg_bs_bp_bp_role .
    TYPES:
      tt_bp_bp_role TYPE SORTED TABLE OF mdg_bs_bp_bp_role WITH NON-UNIQUE KEY bp_header bp_rol_id .
    TYPES ts_bp_bp_taxnum TYPE mdg_bs_bp_bp_taxnum .
    TYPES:
      tt_bp_bp_taxnum TYPE SORTED TABLE OF mdg_bs_bp_bp_taxnum WITH NON-UNIQUE KEY bp_header bp_tx_typ .
    TYPES ts_bp_bp_mlt_as TYPE /mdgbpx/_s_bp_pp_bp_mlt_as .
    TYPES:
      tt_bp_bp_mlt_as TYPE SORTED TABLE OF /mdgbpx/_s_bp_pp_bp_mlt_as WITH NON-UNIQUE KEY bp_header assgnm_id .
    TYPES ts_bp_bp_mlt_ad TYPE /mdgbpx/_s_bp_pp_bp_mlt_ad .
    TYPES:
      tt_bp_bp_mlt_ad TYPE SORTED TABLE OF /mdgbpx/_s_bp_pp_bp_mlt_ad WITH NON-UNIQUE KEY bp_header assgnm_id addrno .
    TYPES ts_bp_bp_cus_cc TYPE mdg_bs_cust_bp_cus_cc .
    TYPES:
      tt_bp_bp_cus_cc TYPE SORTED TABLE OF mdg_bs_cust_bp_cus_cc WITH NON-UNIQUE KEY bp_header assgnm_id company .
    TYPES ts_bp_bp_cuscla TYPE mdg_bs_cust_bp_cuscla .
    TYPES:
      tt_bp_bp_cuscla TYPE SORTED TABLE OF mdg_bs_cust_bp_cuscla WITH NON-UNIQUE KEY bp_header assgnm_id class classtype ecocntr .
    TYPES ts_bp_bp_cusddb TYPE mdg_bs_cust_bp_cusddb .
    TYPES:
      tt_bp_bp_cusddb TYPE SORTED TABLE OF mdg_bs_cust_bp_cusddb WITH NON-UNIQUE KEY bp_header assgnm_id cus_dokar cus_doknr cus_doktl cus_dokvr .
    TYPES ts_bp_bp_cusdun TYPE mdg_bs_cust_bp_cusdun .
    TYPES:
      tt_bp_bp_cusdun TYPE SORTED TABLE OF mdg_bs_cust_bp_cusdun WITH NON-UNIQUE KEY bp_header assgnm_id company maber .
    TYPES ts_bp_bp_cusfcn TYPE mdg_bs_cust_bp_cusfcn .
    TYPES:
      tt_bp_bp_cusfcn TYPE SORTED TABLE OF mdg_bs_cust_bp_cusfcn WITH NON-UNIQUE KEY bp_header assgnm_id spart vkorg vtweg parvw parza .
    TYPES ts_bp_bp_cusgen TYPE mdg_bs_cust_bp_cusgen .
    TYPES:
      tt_bp_bp_cusgen TYPE SORTED TABLE OF mdg_bs_cust_bp_cusgen WITH NON-UNIQUE KEY bp_header assgnm_id .
    TYPES ts_bp_bp_custax TYPE mdg_bs_cust_bp_custax .
    TYPES:
      tt_bp_bp_custax TYPE SORTED TABLE OF mdg_bs_cust_bp_custax WITH NON-UNIQUE KEY bp_header assgnm_id aland tatyp .
    TYPES ts_bp_bp_cusulp TYPE mdg_bs_cust_bp_cusulp .
    TYPES:
      tt_bp_bp_cusulp TYPE SORTED TABLE OF mdg_bs_cust_bp_cusulp WITH NON-UNIQUE KEY bp_header assgnm_id ablad .
    TYPES ts_bp_bp_cusval TYPE mdg_bs_cust_bp_cusval .
    TYPES:
      tt_bp_bp_cusval TYPE SORTED TABLE OF mdg_bs_cust_bp_cusval WITH NON-UNIQUE KEY bp_header assgnm_id charid classtype ecocntr valcnt .
    TYPES ts_bp_bp_cuswht TYPE mdg_bs_cust_bp_cuswht .
    TYPES:
      tt_bp_bp_cuswht TYPE SORTED TABLE OF mdg_bs_cust_bp_cuswht WITH NON-UNIQUE KEY bp_header assgnm_id company witht .
    TYPES ts_bp_bp_sales TYPE mdg_bs_cust_bp_sales .
    TYPES:
      tt_bp_bp_sales TYPE SORTED TABLE OF mdg_bs_cust_bp_sales WITH NON-UNIQUE KEY bp_header assgnm_id spart vkorg vtweg .
    TYPES ts_bp_cuscctxt TYPE mdg_bs_cust_cuscctxt .
    TYPES:
      tt_bp_cuscctxt TYPE SORTED TABLE OF mdg_bs_cust_cuscctxt WITH NON-UNIQUE KEY bp_header assgnm_id company cuslangu cus_tdid .
    TYPES ts_bp_cusgentxt TYPE mdg_bs_cust_cusgentxt .
    TYPES:
      tt_bp_cusgentxt TYPE SORTED TABLE OF mdg_bs_cust_cusgentxt WITH NON-UNIQUE KEY bp_header assgnm_id cuslangu cus_tdid .
    TYPES ts_bp_cussaltxt TYPE mdg_bs_cust_cussaltxt .
    TYPES:
      tt_bp_cussaltxt TYPE SORTED TABLE OF mdg_bs_cust_cussaltxt WITH NON-UNIQUE KEY bp_header assgnm_id spart vkorg vtweg cuslangu cus_tdid .
    TYPES ts_bp_bp_compny TYPE mdg_bs_suppl_bp_compny .
    TYPES:
      tt_bp_bp_compny TYPE SORTED TABLE OF mdg_bs_suppl_bp_compny WITH NON-UNIQUE KEY bp_header assgnm_id company .
    TYPES ts_bp_bp_dunn TYPE mdg_bs_suppl_bp_dunn .
    TYPES:
      tt_bp_bp_dunn TYPE SORTED TABLE OF mdg_bs_suppl_bp_dunn WITH NON-UNIQUE KEY bp_header assgnm_id company maber .
    TYPES ts_bp_bp_porg TYPE mdg_bs_suppl_bp_porg .
    TYPES:
      tt_bp_bp_porg TYPE SORTED TABLE OF mdg_bs_suppl_bp_porg WITH NON-UNIQUE KEY bp_header assgnm_id prch_org .
    TYPES ts_bp_bp_porg2 TYPE mdg_bs_suppl_bp_porg2 .
    TYPES:
      tt_bp_bp_porg2 TYPE SORTED TABLE OF mdg_bs_suppl_bp_porg2 WITH NON-UNIQUE KEY bp_header assgnm_id prch_org ltsnr werks_d .
    TYPES ts_bp_bp_taxgrp TYPE mdg_bs_suppl_bp_taxgrp .
    TYPES:
      tt_bp_bp_taxgrp TYPE SORTED TABLE OF mdg_bs_suppl_bp_taxgrp WITH NON-UNIQUE KEY bp_header assgnm_id koart taxgr .
    TYPES ts_bp_bp_vencla TYPE mdg_bs_suppl_bp_vencla .
    TYPES:
      tt_bp_bp_vencla TYPE SORTED TABLE OF mdg_bs_suppl_bp_vencla WITH NON-UNIQUE KEY bp_header assgnm_id class classtype ecocntr .
    TYPES ts_bp_bp_venddb TYPE mdg_bs_suppl_bp_venddb .
    TYPES:
      tt_bp_bp_venddb TYPE SORTED TABLE OF mdg_bs_suppl_bp_venddb WITH NON-UNIQUE KEY bp_header assgnm_id ven_dokar ven_doknr ven_doktl ven_dokvr .
    TYPES ts_bp_bp_venfcn TYPE mdg_bs_suppl_bp_venfcn .
    TYPES:
      tt_bp_bp_venfcn TYPE SORTED TABLE OF mdg_bs_suppl_bp_venfcn WITH NON-UNIQUE KEY bp_header assgnm_id prch_org ltsnr parvw parza werks_d .
    TYPES ts_bp_bp_vengen TYPE mdg_bs_suppl_bp_vengen .
    TYPES:
      tt_bp_bp_vengen TYPE SORTED TABLE OF mdg_bs_suppl_bp_vengen WITH NON-UNIQUE KEY bp_header assgnm_id .
    TYPES ts_bp_bp_vensub TYPE mdg_bs_suppl_bp_vensub .
    TYPES:
      tt_bp_bp_vensub TYPE SORTED TABLE OF mdg_bs_suppl_bp_vensub WITH NON-UNIQUE KEY bp_header assgnm_id ltsnr ven_langu .
    TYPES ts_bp_bp_venval TYPE mdg_bs_suppl_bp_venval .
    TYPES:
      tt_bp_bp_venval TYPE SORTED TABLE OF mdg_bs_suppl_bp_venval WITH NON-UNIQUE KEY bp_header assgnm_id charid classtype ecocntr valcnt .
    TYPES ts_bp_bp_whtax TYPE mdg_bs_suppl_bp_whtax .
    TYPES:
      tt_bp_bp_whtax TYPE SORTED TABLE OF mdg_bs_suppl_bp_whtax WITH NON-UNIQUE KEY bp_header assgnm_id company land_1 witht .
    TYPES ts_bp_vencctxt TYPE mdg_bs_suppl_vencctxt .
    TYPES:
      tt_bp_vencctxt TYPE SORTED TABLE OF mdg_bs_suppl_vencctxt WITH NON-UNIQUE KEY bp_header assgnm_id company venlangu ven_tdid .
    TYPES ts_bp_vengentxt TYPE mdg_bs_suppl_vengentxt .
    TYPES:
      tt_bp_vengentxt TYPE SORTED TABLE OF mdg_bs_suppl_vengentxt WITH NON-UNIQUE KEY bp_header assgnm_id venlangu ven_tdid .
    TYPES ts_bp_venpotxt TYPE mdg_bs_suppl_venpotxt .
    TYPES:
      tt_bp_venpotxt TYPE SORTED TABLE OF mdg_bs_suppl_venpotxt WITH NON-UNIQUE KEY bp_header assgnm_id prch_org venlangu ven_tdid .
    TYPES ts_mm_key TYPE /mdgmm/_s_mm_kf_material .
    TYPES:
      tt_mm_key TYPE SORTED TABLE OF /mdgmm/_s_mm_kf_material WITH NON-UNIQUE KEY material .
    TYPES ts_mm_txt TYPE /mdgmm/_st_mm_pp_material .
    TYPES:
      tt_mm_txt TYPE SORTED TABLE OF /mdgmm/_st_mm_pp_material WITH NON-UNIQUE KEY material langu .
    TYPES ts_mm_material TYPE /mdgmm/_s_mm_pp_material .
    TYPES:
      tt_mm_material TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_material WITH NON-UNIQUE KEY material .
    TYPES ts_mm_bscdattxt TYPE /mdgmm/_s_mm_pp_bscdattxt .
    TYPES:
      tt_mm_bscdattxt TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_bscdattxt WITH NON-UNIQUE KEY material langucode .
    TYPES ts_mm_classasgn TYPE /mdgmm/_s_mm_pp_classasgn .
    TYPES:
      tt_mm_classasgn TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_classasgn WITH NON-UNIQUE KEY material changeno class classtype ecocntr guid .
    TYPES ts_mm_intcmnt TYPE /mdgmm/_s_mm_pp_intcmnt .
    TYPES:
      tt_mm_intcmnt TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_intcmnt WITH NON-UNIQUE KEY material langucode .
    TYPES ts_mm_marapurch TYPE /mdgmm/_s_mm_pp_marapurch .
    TYPES:
      tt_mm_marapurch TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_marapurch WITH NON-UNIQUE KEY material .
    TYPES ts_mm_maraqtmng TYPE /mdgmm/_s_mm_pp_maraqtmng .
    TYPES:
      tt_mm_maraqtmng TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_maraqtmng WITH NON-UNIQUE KEY material .
    TYPES ts_mm_marasales TYPE /mdgmm/_s_mm_pp_marasales .
    TYPES:
      tt_mm_marasales TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_marasales WITH NON-UNIQUE KEY material .
    TYPES ts_mm_maraspm TYPE /mdgmm/_s_mm_pp_maraspm .
    TYPES:
      tt_mm_maraspm TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_maraspm WITH NON-UNIQUE KEY material .
    TYPES ts_mm_marastor TYPE /mdgmm/_s_mm_pp_marastor .
    TYPES:
      tt_mm_marastor TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_marastor WITH NON-UNIQUE KEY material .
    TYPES ts_mm_marcatp TYPE /mdgmm/_s_mm_pp_marcatp .
    TYPES:
      tt_mm_marcatp TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_marcatp WITH NON-UNIQUE KEY material werks .
    TYPES ts_mm_marcbasic TYPE /mdgmm/_s_mm_pp_marcbasic .
    TYPES:
      tt_mm_marcbasic TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_marcbasic WITH NON-UNIQUE KEY material werks .
    TYPES ts_mm_marccstng TYPE /mdgmm/_s_mm_pp_marccstng .
    TYPES:
      tt_mm_marccstng TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_marccstng WITH NON-UNIQUE KEY material werks .
    TYPES ts_mm_marcfrcst TYPE /mdgmm/_s_mm_pp_marcfrcst .
    TYPES:
      tt_mm_marcfrcst TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_marcfrcst WITH NON-UNIQUE KEY material werks .
    TYPES ts_mm_marcfrgtr TYPE /mdgmm/_s_mm_pp_marcfrgtr .
    TYPES:
      tt_mm_marcfrgtr TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_marcfrgtr WITH NON-UNIQUE KEY material werks .
    TYPES ts_mm_marcfrpar TYPE /mdgmm/_s_mm_pp_marcfrpar .
    TYPES:
      tt_mm_marcfrpar TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_marcfrpar WITH NON-UNIQUE KEY material werks .
    TYPES ts_mm_marcmrpfc TYPE /mdgmm/_s_mm_pp_marcmrpfc .
    TYPES:
      tt_mm_marcmrpfc TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_marcmrpfc WITH NON-UNIQUE KEY material werks .
    TYPES ts_mm_marcmrpls TYPE /mdgmm/_s_mm_pp_marcmrpls .
    TYPES:
      tt_mm_marcmrpls TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_marcmrpls WITH NON-UNIQUE KEY material werks .
    TYPES ts_mm_marcmrpmi TYPE /mdgmm/_s_mm_pp_marcmrpmi .
    TYPES:
      tt_mm_marcmrpmi TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_marcmrpmi WITH NON-UNIQUE KEY material werks .
    TYPES ts_mm_marcmrppp TYPE /mdgmm/_s_mm_pp_marcmrppp .
    TYPES:
      tt_mm_marcmrppp TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_marcmrppp WITH NON-UNIQUE KEY material werks .
    TYPES ts_mm_marcmrpsp TYPE /mdgmm/_s_mm_pp_marcmrpsp .
    TYPES:
      tt_mm_marcmrpsp TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_marcmrpsp WITH NON-UNIQUE KEY material werks .
    TYPES ts_mm_marcprt TYPE /mdgmm/_s_mm_pp_marcprt .
    TYPES:
      tt_mm_marcprt TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_marcprt WITH NON-UNIQUE KEY material werks .
    TYPES ts_mm_marcpurch TYPE /mdgmm/_s_mm_pp_marcpurch .
    TYPES:
      tt_mm_marcpurch TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_marcpurch WITH NON-UNIQUE KEY material werks .
    TYPES ts_mm_marcqtmng TYPE /mdgmm/_s_mm_pp_marcqtmng .
    TYPES:
      tt_mm_marcqtmng TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_marcqtmng WITH NON-UNIQUE KEY material werks .
    TYPES ts_mm_marcsales TYPE /mdgmm/_s_mm_pp_marcsales .
    TYPES:
      tt_mm_marcsales TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_marcsales WITH NON-UNIQUE KEY material werks .
    TYPES ts_mm_marcstore TYPE /mdgmm/_s_mm_pp_marcstore .
    TYPES:
      tt_mm_marcstore TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_marcstore WITH NON-UNIQUE KEY material werks .
    TYPES ts_mm_marcwrksd TYPE /mdgmm/_s_mm_pp_marcwrksd .
    TYPES:
      tt_mm_marcwrksd TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_marcwrksd WITH NON-UNIQUE KEY material werks .
    TYPES ts_mm_mardmrp TYPE /mdgmm/_s_mm_pp_mardmrp .
    TYPES:
      tt_mm_mardmrp TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_mardmrp WITH NON-UNIQUE KEY material werks lgort .
    TYPES ts_mm_mardstor TYPE /mdgmm/_s_mm_pp_mardstor .
    TYPES:
      tt_mm_mardstor TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_mardstor WITH NON-UNIQUE KEY material werks lgort .
    TYPES ts_mm_mbewactng TYPE /mdgmm/_s_mm_pp_mbewactng .
    TYPES:
      tt_mm_mbewactng TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_mbewactng WITH NON-UNIQUE KEY material bwkey bwtar .
    TYPES ts_mm_mbewcstng TYPE /mdgmm/_s_mm_pp_mbewcstng .
    TYPES:
      tt_mm_mbewcstng TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_mbewcstng WITH NON-UNIQUE KEY material bwkey .
    TYPES ts_mm_mbewmlac TYPE /mdgmm/_s_mm_pp_mbewmlac .
    TYPES:
      tt_mm_mbewmlac TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_mbewmlac WITH NON-UNIQUE KEY material bwkey bwtar curtp .
    TYPES ts_mm_mbewmlval TYPE /mdgmm/_s_mm_pp_mbewmlval .
    TYPES:
      tt_mm_mbewmlval TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_mbewmlval WITH NON-UNIQUE KEY material bwkey bwtar curtp .
    TYPES ts_mm_mbewvalua TYPE /mdgmm/_s_mm_pp_mbewvalua .
    TYPES:
      tt_mm_mbewvalua TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_mbewvalua WITH NON-UNIQUE KEY material bwkey bwtar .
    TYPES ts_mm_mdmabasic TYPE /mdgmm/_s_mm_pp_mdmabasic .
    TYPES:
      tt_mm_mdmabasic TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_mdmabasic WITH NON-UNIQUE KEY material werks berid .
    TYPES ts_mm_mean_gtin TYPE /mdgmm/_s_mm_pp_mean_gtin .
    TYPES:
      tt_mm_mean_gtin TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_mean_gtin WITH NON-UNIQUE KEY material qteunit ean .
    TYPES ts_mm_mlanpurch TYPE /mdgmm/_s_mm_pp_mlanpurch .
    TYPES:
      tt_mm_mlanpurch TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_mlanpurch WITH NON-UNIQUE KEY material aland .
    TYPES ts_mm_mlansales TYPE /mdgmm/_s_mm_pp_mlansales .
    TYPES:
      tt_mm_mlansales TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_mlansales WITH NON-UNIQUE KEY material aland tatyp .
    TYPES ts_mm_mlgnstor TYPE /mdgmm/_s_mm_pp_mlgnstor .
    TYPES:
      tt_mm_mlgnstor TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_mlgnstor WITH NON-UNIQUE KEY material lgnum .
    TYPES ts_mm_mlgtstor TYPE /mdgmm/_s_mm_pp_mlgtstor .
    TYPES:
      tt_mm_mlgtstor TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_mlgtstor WITH NON-UNIQUE KEY material lgnum lgtyp .
    TYPES ts_mm_mpgdprodg TYPE /mdgmm/_s_mm_pp_mpgdprodg .
    TYPES:
      tt_mm_mpgdprodg TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_mpgdprodg WITH NON-UNIQUE KEY material werks .
    TYPES ts_mm_mrptxt TYPE /mdgmm/_s_mm_pp_mrptxt .
    TYPES:
      tt_mm_mrptxt TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_mrptxt WITH NON-UNIQUE KEY material werks .
    TYPES ts_mm_mvkegrpng TYPE /mdgmm/_s_mm_pp_mvkegrpng .
    TYPES:
      tt_mm_mvkegrpng TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_mvkegrpng WITH NON-UNIQUE KEY material vkorg vtweg .
    TYPES ts_mm_mvkesales TYPE /mdgmm/_s_mm_pp_mvkesales .
    TYPES:
      tt_mm_mvkesales TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_mvkesales WITH NON-UNIQUE KEY material vkorg vtweg .
    TYPES ts_mm_purchtxt TYPE /mdgmm/_s_mm_pp_purchtxt .
    TYPES:
      tt_mm_purchtxt TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_purchtxt WITH NON-UNIQUE KEY material langucode .
    TYPES ts_mm_qinsptxt TYPE /mdgmm/_s_mm_pp_qinsptxt .
    TYPES:
      tt_mm_qinsptxt TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_qinsptxt WITH NON-UNIQUE KEY material langucode .
    TYPES ts_mm_qmatbasic TYPE /mdgmm/_s_mm_pp_qmatbasic .
    TYPES:
      tt_mm_qmatbasic TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_qmatbasic WITH NON-UNIQUE KEY material werks art .
    TYPES ts_mm_salestxt TYPE /mdgmm/_s_mm_pp_salestxt .
    TYPES:
      tt_mm_salestxt TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_salestxt WITH NON-UNIQUE KEY material vkorg vtweg langucode .
    TYPES ts_mm_unitofmsr TYPE /mdgmm/_s_mm_pp_unitofmsr .
    TYPES:
      tt_mm_unitofmsr TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_unitofmsr WITH NON-UNIQUE KEY material qteunit .
    TYPES ts_mm_valuation TYPE /mdgmm/_s_mm_pp_valuation .
    TYPES:
      tt_mm_valuation TYPE SORTED TABLE OF /mdgmm/_s_mm_pp_valuation WITH NON-UNIQUE KEY material changeno charid classtype ecocntr guid valcnt .

    CLASS-DATA gv_debug_mode TYPE flag .

    CLASS-METHODS get_cr_from_key
      IMPORTING
        !iv_model       TYPE usmd_model
        !iv_main_entity TYPE usmd_entity
        !is_key         TYPE data
      RETURNING
        VALUE(rv_cr)    TYPE usmd_crequest .
    CLASS-METHODS get_t_sel_from_conv_api
      RETURNING
        VALUE(rt_sel) TYPE usmd_ts_sel .
    CLASS-METHODS read_entity
      IMPORTING
        !iv_entity TYPE clike
      EXPORTING
        !et_data   TYPE ANY TABLE .
    CLASS-METHODS read_bp
      IMPORTING
        !iv_key           TYPE bu_partner OPTIONAL
        !it_key           TYPE rpm_tt_bupa OPTIONAL
        !iv_read_inactive TYPE flag OPTIONAL
      EXPORTING
        !es_bp_header     TYPE ts_bp_bp_header
        !et_key           TYPE tt_bp_key
        !et_bp_header     TYPE tt_bp_bp_header
        !et_ad_email      TYPE tt_bp_ad_email
        !et_ad_fax        TYPE tt_bp_ad_fax
        !et_ad_name_o     TYPE tt_bp_ad_name_o
        !et_ad_name_p     TYPE tt_bp_ad_name_p
        !et_ad_postal     TYPE tt_bp_ad_postal
        !et_ad_tel        TYPE tt_bp_ad_tel
        !et_ad_url        TYPE tt_bp_ad_url
        !et_address       TYPE tt_bp_address
        !et_bp_addr       TYPE tt_bp_bp_addr
        !et_bp_addusg     TYPE tt_bp_bp_addusg
        !et_bp_bkdtl      TYPE tt_bp_bp_bkdtl
        !et_bp_ccdtl      TYPE tt_bp_bp_ccdtl
        !et_bp_centrl     TYPE tt_bp_bp_centrl
        !et_bp_idnum      TYPE tt_bp_bp_idnum
        !et_bp_indstr     TYPE tt_bp_bp_indstr
        !et_bp_role       TYPE tt_bp_bp_role
        !et_bp_taxnum     TYPE tt_bp_bp_taxnum
        !et_bp_mlt_as     TYPE tt_bp_bp_mlt_as
        !et_bp_mlt_ad     TYPE tt_bp_bp_mlt_ad
        !et_bp_cus_cc     TYPE tt_bp_bp_cus_cc
        !et_bp_cuscla     TYPE tt_bp_bp_cuscla
        !et_bp_cusddb     TYPE tt_bp_bp_cusddb
        !et_bp_cusdun     TYPE tt_bp_bp_cusdun
        !et_bp_cusfcn     TYPE tt_bp_bp_cusfcn
        !et_bp_cusgen     TYPE tt_bp_bp_cusgen
        !et_bp_custax     TYPE tt_bp_bp_custax
        !et_bp_cusulp     TYPE tt_bp_bp_cusulp
        !et_bp_cusval     TYPE tt_bp_bp_cusval
        !et_bp_cuswht     TYPE tt_bp_bp_cuswht
        !et_bp_sales      TYPE tt_bp_bp_sales
        !et_cuscctxt      TYPE tt_bp_cuscctxt
        !et_cusgentxt     TYPE tt_bp_cusgentxt
        !et_cussaltxt     TYPE tt_bp_cussaltxt
        !et_bp_compny     TYPE tt_bp_bp_compny
        !et_bp_dunn       TYPE tt_bp_bp_dunn
        !et_bp_porg       TYPE tt_bp_bp_porg
        !et_bp_porg2      TYPE tt_bp_bp_porg2
        !et_bp_taxgrp     TYPE tt_bp_bp_taxgrp
        !et_bp_vencla     TYPE tt_bp_bp_vencla
        !et_bp_venddb     TYPE tt_bp_bp_venddb
        !et_bp_venfcn     TYPE tt_bp_bp_venfcn
        !et_bp_vengen     TYPE tt_bp_bp_vengen
        !et_bp_vensub     TYPE tt_bp_bp_vensub
        !et_bp_venval     TYPE tt_bp_bp_venval
        !et_bp_whtax      TYPE tt_bp_bp_whtax
        !et_vencctxt      TYPE tt_bp_vencctxt
        !et_vengentxt     TYPE tt_bp_vengentxt
        !et_venpotxt      TYPE tt_bp_venpotxt .
    CLASS-METHODS read_mm
      IMPORTING
        !iv_key           TYPE matnr OPTIONAL
        !it_key           TYPE matnr_tab OPTIONAL
        !iv_read_inactive TYPE flag OPTIONAL
      EXPORTING
        !es_material      TYPE ts_mm_material
        !et_key           TYPE tt_mm_key
        !et_txt           TYPE tt_mm_txt
        !et_material      TYPE tt_mm_material
        !et_bscdattxt     TYPE tt_mm_bscdattxt
        !et_classasgn     TYPE tt_mm_classasgn
        !et_intcmnt       TYPE tt_mm_intcmnt
        !et_marapurch     TYPE tt_mm_marapurch
        !et_maraqtmng     TYPE tt_mm_maraqtmng
        !et_marasales     TYPE tt_mm_marasales
        !et_maraspm       TYPE tt_mm_maraspm
        !et_marastor      TYPE tt_mm_marastor
        !et_marcatp       TYPE tt_mm_marcatp
        !et_marcbasic     TYPE tt_mm_marcbasic
        !et_marccstng     TYPE tt_mm_marccstng
        !et_marcfrcst     TYPE tt_mm_marcfrcst
        !et_marcfrgtr     TYPE tt_mm_marcfrgtr
        !et_marcfrpar     TYPE tt_mm_marcfrpar
        !et_marcmrpfc     TYPE tt_mm_marcmrpfc
        !et_marcmrpls     TYPE tt_mm_marcmrpls
        !et_marcmrpmi     TYPE tt_mm_marcmrpmi
        !et_marcmrppp     TYPE tt_mm_marcmrppp
        !et_marcmrpsp     TYPE tt_mm_marcmrpsp
        !et_marcprt       TYPE tt_mm_marcprt
        !et_marcpurch     TYPE tt_mm_marcpurch
        !et_marcqtmng     TYPE tt_mm_marcqtmng
        !et_marcsales     TYPE tt_mm_marcsales
        !et_marcstore     TYPE tt_mm_marcstore
        !et_marcwrksd     TYPE tt_mm_marcwrksd
        !et_mardmrp       TYPE tt_mm_mardmrp
        !et_mardstor      TYPE tt_mm_mardstor
        !et_mbewactng     TYPE tt_mm_mbewactng
        !et_mbewcstng     TYPE tt_mm_mbewcstng
        !et_mbewmlac      TYPE tt_mm_mbewmlac
        !et_mbewmlval     TYPE tt_mm_mbewmlval
        !et_mbewvalua     TYPE tt_mm_mbewvalua
        !et_mdmabasic     TYPE tt_mm_mdmabasic
        !et_mean_gtin     TYPE tt_mm_mean_gtin
        !et_mlanpurch     TYPE tt_mm_mlanpurch
        !et_mlansales     TYPE tt_mm_mlansales
        !et_mlgnstor      TYPE tt_mm_mlgnstor
        !et_mlgtstor      TYPE tt_mm_mlgtstor
        !et_mpgdprodg     TYPE tt_mm_mpgdprodg
        !et_mrptxt        TYPE tt_mm_mrptxt
        !et_mvkegrpng     TYPE tt_mm_mvkegrpng
        !et_mvkesales     TYPE tt_mm_mvkesales
        !et_purchtxt      TYPE tt_mm_purchtxt
        !et_qinsptxt      TYPE tt_mm_qinsptxt
        !et_qmatbasic     TYPE tt_mm_qmatbasic
        !et_salestxt      TYPE tt_mm_salestxt
        !et_unitofmsr     TYPE tt_mm_unitofmsr
        !et_valuation     TYPE tt_mm_valuation .
  PROTECTED SECTION.
  PRIVATE SECTION.
ENDCLASS.



CLASS ZCL_MDP_READ_HELPER IMPLEMENTATION.


* <SIGNATURE>---------------------------------------------------------------------------------------+
* | Static Public Method ZCL_MDP_READ_HELPER=>GET_CR_FROM_KEY
* +-------------------------------------------------------------------------------------------------+
* | [--->] IV_MODEL                       TYPE        USMD_MODEL
* | [--->] IV_MAIN_ENTITY                 TYPE        USMD_ENTITY
* | [--->] IS_KEY                         TYPE        DATA
* | [<-()] RV_CR                          TYPE        USMD_CREQUEST
* +--------------------------------------------------------------------------------------</SIGNATURE>
  METHOD get_cr_from_key.
    DATA: lt_crequest_id TYPE usmd_cr_ts_root_node_id.

*IV_OBJECT_TYPE	TYPE USMD_OBJECT
*IS_OBJECT_KEY  TYPE DATA
*IV_MODEL	TYPE USMD_MODEL
*value( RT_CREQUEST_ID )  TYPE USMD_CR_TS_ROOT_NODE_ID
    cl_usmd_cr_factory=>get_cr_service_provider( )->if_usmd_cr_sp_query~retrieve_open_cr_by_object_key(
      EXPORTING
        iv_object_type = iv_main_entity
        is_object_key  = is_key
        iv_model       = iv_model
      RECEIVING
        rt_crequest_id = lt_crequest_id
    ).
*    CATCH cx_usmd_cr_root_no_model_insta. " no model instance for model name
*    CATCH cx_usmd_cr_root_bad_entity_typ. " Illegal entity typ
*    CATCH cx_usmd_cr_root_emp_entity_key. " Initial entity key.

    CHECK: lt_crequest_id IS NOT INITIAL.
    rv_cr = lt_crequest_id[ 1 ]-usmd_crequest.

  ENDMETHOD.


* <SIGNATURE>---------------------------------------------------------------------------------------+
* | Static Public Method ZCL_MDP_READ_HELPER=>GET_T_SEL_FROM_CONV_API
* +-------------------------------------------------------------------------------------------------+
* | [<-()] RT_SEL                         TYPE        USMD_TS_SEL
* +--------------------------------------------------------------------------------------</SIGNATURE>
  METHOD get_t_sel_from_conv_api.
    DATA: lo_conv_api             TYPE REF TO if_usmd_conv_som_gov_api,
          lt_object_list_db_style TYPE usmd_t_crequest_entity,
          ls_object_list_db_style TYPE usmd_s_crequest_entity,
          ls_sel                  TYPE usmd_s_sel.

    TRY.
        lo_conv_api = cl_usmd_conv_som_gov_api=>get_instance( ).
        lo_conv_api->get_object_list(
          IMPORTING
            et_object_list_db_style = lt_object_list_db_style " Change Request, Entity, Table Type
        ).
        ls_sel-sign = 'I'.
        ls_sel-option = 'EQ'.
        LOOP AT lt_object_list_db_style INTO ls_object_list_db_style WHERE usmd_entity = lo_conv_api->mv_main_entity.
          ls_sel-fieldname = ls_object_list_db_style-usmd_entity_obj.
          ls_sel-low = ls_object_list_db_style-usmd_value.
          INSERT ls_sel INTO TABLE rt_sel.
        ENDLOOP.

      CATCH cx_usmd_gov_api.                " General Processing Error GOV_API

    ENDTRY.

  ENDMETHOD.


* <SIGNATURE>---------------------------------------------------------------------------------------+
* | Static Public Method ZCL_MDP_READ_HELPER=>READ_BP
* +-------------------------------------------------------------------------------------------------+
* | [--->] IV_KEY                         TYPE        BU_PARTNER(optional)
* | [--->] IT_KEY                         TYPE        RPM_TT_BUPA(optional)
* | [--->] IV_READ_INACTIVE               TYPE        FLAG(optional)
* | [<---] ES_BP_HEADER                   TYPE        TS_BP_BP_HEADER
* | [<---] ET_KEY                         TYPE        TT_BP_KEY
* | [<---] ET_BP_HEADER                   TYPE        TT_BP_BP_HEADER
* | [<---] ET_AD_EMAIL                    TYPE        TT_BP_AD_EMAIL
* | [<---] ET_AD_FAX                      TYPE        TT_BP_AD_FAX
* | [<---] ET_AD_NAME_O                   TYPE        TT_BP_AD_NAME_O
* | [<---] ET_AD_NAME_P                   TYPE        TT_BP_AD_NAME_P
* | [<---] ET_AD_POSTAL                   TYPE        TT_BP_AD_POSTAL
* | [<---] ET_AD_TEL                      TYPE        TT_BP_AD_TEL
* | [<---] ET_AD_URL                      TYPE        TT_BP_AD_URL
* | [<---] ET_ADDRESS                     TYPE        TT_BP_ADDRESS
* | [<---] ET_BP_ADDR                     TYPE        TT_BP_BP_ADDR
* | [<---] ET_BP_ADDUSG                   TYPE        TT_BP_BP_ADDUSG
* | [<---] ET_BP_BKDTL                    TYPE        TT_BP_BP_BKDTL
* | [<---] ET_BP_CCDTL                    TYPE        TT_BP_BP_CCDTL
* | [<---] ET_BP_CENTRL                   TYPE        TT_BP_BP_CENTRL
* | [<---] ET_BP_IDNUM                    TYPE        TT_BP_BP_IDNUM
* | [<---] ET_BP_INDSTR                   TYPE        TT_BP_BP_INDSTR
* | [<---] ET_BP_ROLE                     TYPE        TT_BP_BP_ROLE
* | [<---] ET_BP_TAXNUM                   TYPE        TT_BP_BP_TAXNUM
* | [<---] ET_BP_MLT_AS                   TYPE        TT_BP_BP_MLT_AS
* | [<---] ET_BP_MLT_AD                   TYPE        TT_BP_BP_MLT_AD
* | [<---] ET_BP_CUS_CC                   TYPE        TT_BP_BP_CUS_CC
* | [<---] ET_BP_CUSCLA                   TYPE        TT_BP_BP_CUSCLA
* | [<---] ET_BP_CUSDDB                   TYPE        TT_BP_BP_CUSDDB
* | [<---] ET_BP_CUSDUN                   TYPE        TT_BP_BP_CUSDUN
* | [<---] ET_BP_CUSFCN                   TYPE        TT_BP_BP_CUSFCN
* | [<---] ET_BP_CUSGEN                   TYPE        TT_BP_BP_CUSGEN
* | [<---] ET_BP_CUSTAX                   TYPE        TT_BP_BP_CUSTAX
* | [<---] ET_BP_CUSULP                   TYPE        TT_BP_BP_CUSULP
* | [<---] ET_BP_CUSVAL                   TYPE        TT_BP_BP_CUSVAL
* | [<---] ET_BP_CUSWHT                   TYPE        TT_BP_BP_CUSWHT
* | [<---] ET_BP_SALES                    TYPE        TT_BP_BP_SALES
* | [<---] ET_CUSCCTXT                    TYPE        TT_BP_CUSCCTXT
* | [<---] ET_CUSGENTXT                   TYPE        TT_BP_CUSGENTXT
* | [<---] ET_CUSSALTXT                   TYPE        TT_BP_CUSSALTXT
* | [<---] ET_BP_COMPNY                   TYPE        TT_BP_BP_COMPNY
* | [<---] ET_BP_DUNN                     TYPE        TT_BP_BP_DUNN
* | [<---] ET_BP_PORG                     TYPE        TT_BP_BP_PORG
* | [<---] ET_BP_PORG2                    TYPE        TT_BP_BP_PORG2
* | [<---] ET_BP_TAXGRP                   TYPE        TT_BP_BP_TAXGRP
* | [<---] ET_BP_VENCLA                   TYPE        TT_BP_BP_VENCLA
* | [<---] ET_BP_VENDDB                   TYPE        TT_BP_BP_VENDDB
* | [<---] ET_BP_VENFCN                   TYPE        TT_BP_BP_VENFCN
* | [<---] ET_BP_VENGEN                   TYPE        TT_BP_BP_VENGEN
* | [<---] ET_BP_VENSUB                   TYPE        TT_BP_BP_VENSUB
* | [<---] ET_BP_VENVAL                   TYPE        TT_BP_BP_VENVAL
* | [<---] ET_BP_WHTAX                    TYPE        TT_BP_BP_WHTAX
* | [<---] ET_VENCCTXT                    TYPE        TT_BP_VENCCTXT
* | [<---] ET_VENGENTXT                   TYPE        TT_BP_VENGENTXT
* | [<---] ET_VENPOTXT                    TYPE        TT_BP_VENPOTXT
* +--------------------------------------------------------------------------------------</SIGNATURE>
  METHOD read_bp.
    DATA: lo_model_ext TYPE REF TO if_usmd_model_ext,
          lt_sel       TYPE usmd_ts_sel,
          ls_sel       TYPE usmd_s_sel,
          lv_readmode  TYPE usmd_readmode_ext  VALUE if_usmd_model_ext=>gc_readmode_default,
          lv_key       LIKE LINE OF it_key.
    FIELD-SYMBOLS: <ls_key> LIKE LINE OF et_key.

    CLEAR: et_key, et_bp_header, es_bp_header.

    cl_usmd_model_ext=>get_instance(
      EXPORTING
        i_usmd_model = 'BP'
      IMPORTING
        eo_instance  = lo_model_ext
    ).
    CHECK: lo_model_ext IS NOT INITIAL.

    ls_sel-fieldname = 'BP_HEADER'.
    ls_sel-sign = 'I'.
    ls_sel-option = 'EQ'.

    IF iv_key IS NOT INITIAL.
      ls_sel-low = iv_key.
      INSERT ls_sel INTO TABLE lt_sel.
    ENDIF.

    IF it_key IS NOT INITIAL.
      LOOP AT it_key INTO lv_key.
        ls_sel-low = lv_key.
        INSERT ls_sel INTO TABLE lt_sel.
      ENDLOOP.
    ENDIF.

    IF lt_sel IS INITIAL.
      lt_sel = get_t_sel_from_conv_api( ).
    ENDIF.

    CHECK: lt_sel IS NOT INITIAL.

    IF iv_read_inactive EQ abap_true.
      lv_readmode = if_usmd_model_ext=>gc_readmode_no_act.

      lo_model_ext->read_char_value(
        EXPORTING
          i_fieldname       = 'BP_HEADER'
          it_sel            = lt_sel
          i_readmode        = lv_readmode
        IMPORTING
          et_data           = et_key
      ).
      CHECK: et_key IS NOT INITIAL.
      IF lines( lt_sel ) <> lines( et_key ).
        CLEAR: lt_sel.
        LOOP AT et_key ASSIGNING <ls_key>.
          ls_sel-low = <ls_key>-bp_header.
          INSERT ls_sel INTO TABLE lt_sel.
        ENDLOOP.
      ENDIF.

      lv_readmode = if_usmd_model_ext=>gc_readmode_all_inact.
    ENDIF.

    lo_model_ext->read_char_value(
      EXPORTING
        i_fieldname       = 'BP_HEADER'
        it_sel            = lt_sel
        i_readmode        = lv_readmode
      IMPORTING
        et_data           = et_bp_header
    ).
    CHECK: et_bp_header IS NOT INITIAL.
    READ TABLE et_bp_header INTO es_bp_header INDEX 1.
    MOVE-CORRESPONDING et_bp_header TO et_key.


*    IF et_bp_centrl IS SUPPLIED.
*      CLEAR: et_bp_centrl.
*      lo_model_ext->read_char_value(
*        EXPORTING
*          i_fieldname       = 'BP_CENTRL'
*          it_sel            = lt_sel
*          i_readmode        = lv_readmode
*        IMPORTING
*          et_data           = et_bp_centrl
*      ).
*    ENDIF.
    DEFINE __read.
      IF gv_debug_mode EQ abap_true OR et_&1 IS SUPPLIED.
        CLEAR: et_&1.
        lo_model_ext->read_char_value(
          EXPORTING
            i_fieldname       = '&1'
            it_sel            = lt_sel
            i_readmode        = lv_readmode
          IMPORTING
            et_data           = et_&1
        ).
      ENDIF.
    END-OF-DEFINITION.


    __read ad_email.
    __read ad_fax.
    __read ad_name_o.
    __read ad_name_p.
    __read ad_postal.
    __read ad_tel.
    __read ad_url.
    __read address.
    __read bp_addr.
    __read bp_addusg.
    __read bp_bkdtl.
    __read bp_ccdtl.
    __read bp_centrl.
    __read bp_idnum.
    __read bp_indstr.
    __read bp_role.
    __read bp_taxnum.
    __read bp_mlt_as.
    __read bp_mlt_ad.
    __read bp_cus_cc.
    __read bp_cuscla.
    __read bp_cusddb.
    __read bp_cusdun.
    __read bp_cusfcn.
    __read bp_cusgen.
    __read bp_custax.
    __read bp_cusulp.
    __read bp_cusval.
    __read bp_cuswht.
    __read bp_sales.
    __read cuscctxt.
    __read cusgentxt.
    __read cussaltxt.
    __read bp_compny.
    __read bp_dunn.
    __read bp_porg.
    __read bp_porg2.
    __read bp_taxgrp.
    __read bp_vencla.
    __read bp_venddb.
    __read bp_venfcn.
    __read bp_vengen.
    __read bp_vensub.
    __read bp_venval.
    __read bp_whtax.
    __read vencctxt.
    __read vengentxt.
    __read venpotxt.


    IF gv_debug_mode EQ abap_true.
      BREAK-POINT.
    ENDIF.
  ENDMETHOD.


* <SIGNATURE>---------------------------------------------------------------------------------------+
* | Static Public Method ZCL_MDP_READ_HELPER=>READ_ENTITY
* +-------------------------------------------------------------------------------------------------+
* | [--->] IV_ENTITY                      TYPE        CLIKE
* | [<---] ET_DATA                        TYPE        ANY TABLE
* +--------------------------------------------------------------------------------------</SIGNATURE>
  METHOD read_entity.
    DATA: lo_mdg_api   TYPE REF TO if_usmd_conv_som_gov_api,
          lo_model_api TYPE REF TO if_usmd_model_ext,
          lt_sel       TYPE usmd_ts_sel.

    CLEAR: et_data.

    TRY.
        lo_mdg_api = cl_usmd_conv_som_gov_api=>get_instance( ).
      CATCH cx_usmd_gov_api.
        RETURN.
    ENDTRY.
    CHECK: lo_mdg_api IS NOT INITIAL.

    cl_usmd_model_ext=>get_instance(
      EXPORTING
        i_usmd_model = lo_mdg_api->mv_model_name
      IMPORTING
        eo_instance  = lo_model_api
    ).
    CHECK: lo_model_api IS NOT INITIAL.

    lt_sel = get_t_sel_from_conv_api( ).

    lo_model_api->read_char_value(
      EXPORTING
        i_fieldname       = CONV #( iv_entity )
        it_sel            = lt_sel
      IMPORTING
        et_data           = et_data
    ).
  ENDMETHOD.


* <SIGNATURE>---------------------------------------------------------------------------------------+
* | Static Public Method ZCL_MDP_READ_HELPER=>READ_MM
* +-------------------------------------------------------------------------------------------------+
* | [--->] IV_KEY                         TYPE        MATNR(optional)
* | [--->] IT_KEY                         TYPE        MATNR_TAB(optional)
* | [--->] IV_READ_INACTIVE               TYPE        FLAG(optional)
* | [<---] ES_MATERIAL                    TYPE        TS_MM_MATERIAL
* | [<---] ET_KEY                         TYPE        TT_MM_KEY
* | [<---] ET_TXT                         TYPE        TT_MM_TXT
* | [<---] ET_MATERIAL                    TYPE        TT_MM_MATERIAL
* | [<---] ET_BSCDATTXT                   TYPE        TT_MM_BSCDATTXT
* | [<---] ET_CLASSASGN                   TYPE        TT_MM_CLASSASGN
* | [<---] ET_INTCMNT                     TYPE        TT_MM_INTCMNT
* | [<---] ET_MARAPURCH                   TYPE        TT_MM_MARAPURCH
* | [<---] ET_MARAQTMNG                   TYPE        TT_MM_MARAQTMNG
* | [<---] ET_MARASALES                   TYPE        TT_MM_MARASALES
* | [<---] ET_MARASPM                     TYPE        TT_MM_MARASPM
* | [<---] ET_MARASTOR                    TYPE        TT_MM_MARASTOR
* | [<---] ET_MARCATP                     TYPE        TT_MM_MARCATP
* | [<---] ET_MARCBASIC                   TYPE        TT_MM_MARCBASIC
* | [<---] ET_MARCCSTNG                   TYPE        TT_MM_MARCCSTNG
* | [<---] ET_MARCFRCST                   TYPE        TT_MM_MARCFRCST
* | [<---] ET_MARCFRGTR                   TYPE        TT_MM_MARCFRGTR
* | [<---] ET_MARCFRPAR                   TYPE        TT_MM_MARCFRPAR
* | [<---] ET_MARCMRPFC                   TYPE        TT_MM_MARCMRPFC
* | [<---] ET_MARCMRPLS                   TYPE        TT_MM_MARCMRPLS
* | [<---] ET_MARCMRPMI                   TYPE        TT_MM_MARCMRPMI
* | [<---] ET_MARCMRPPP                   TYPE        TT_MM_MARCMRPPP
* | [<---] ET_MARCMRPSP                   TYPE        TT_MM_MARCMRPSP
* | [<---] ET_MARCPRT                     TYPE        TT_MM_MARCPRT
* | [<---] ET_MARCPURCH                   TYPE        TT_MM_MARCPURCH
* | [<---] ET_MARCQTMNG                   TYPE        TT_MM_MARCQTMNG
* | [<---] ET_MARCSALES                   TYPE        TT_MM_MARCSALES
* | [<---] ET_MARCSTORE                   TYPE        TT_MM_MARCSTORE
* | [<---] ET_MARCWRKSD                   TYPE        TT_MM_MARCWRKSD
* | [<---] ET_MARDMRP                     TYPE        TT_MM_MARDMRP
* | [<---] ET_MARDSTOR                    TYPE        TT_MM_MARDSTOR
* | [<---] ET_MBEWACTNG                   TYPE        TT_MM_MBEWACTNG
* | [<---] ET_MBEWCSTNG                   TYPE        TT_MM_MBEWCSTNG
* | [<---] ET_MBEWMLAC                    TYPE        TT_MM_MBEWMLAC
* | [<---] ET_MBEWMLVAL                   TYPE        TT_MM_MBEWMLVAL
* | [<---] ET_MBEWVALUA                   TYPE        TT_MM_MBEWVALUA
* | [<---] ET_MDMABASIC                   TYPE        TT_MM_MDMABASIC
* | [<---] ET_MEAN_GTIN                   TYPE        TT_MM_MEAN_GTIN
* | [<---] ET_MLANPURCH                   TYPE        TT_MM_MLANPURCH
* | [<---] ET_MLANSALES                   TYPE        TT_MM_MLANSALES
* | [<---] ET_MLGNSTOR                    TYPE        TT_MM_MLGNSTOR
* | [<---] ET_MLGTSTOR                    TYPE        TT_MM_MLGTSTOR
* | [<---] ET_MPGDPRODG                   TYPE        TT_MM_MPGDPRODG
* | [<---] ET_MRPTXT                      TYPE        TT_MM_MRPTXT
* | [<---] ET_MVKEGRPNG                   TYPE        TT_MM_MVKEGRPNG
* | [<---] ET_MVKESALES                   TYPE        TT_MM_MVKESALES
* | [<---] ET_PURCHTXT                    TYPE        TT_MM_PURCHTXT
* | [<---] ET_QINSPTXT                    TYPE        TT_MM_QINSPTXT
* | [<---] ET_QMATBASIC                   TYPE        TT_MM_QMATBASIC
* | [<---] ET_SALESTXT                    TYPE        TT_MM_SALESTXT
* | [<---] ET_UNITOFMSR                   TYPE        TT_MM_UNITOFMSR
* | [<---] ET_VALUATION                   TYPE        TT_MM_VALUATION
* +--------------------------------------------------------------------------------------</SIGNATURE>
  METHOD read_mm.
    DATA: lo_model_ext TYPE REF TO if_usmd_model_ext,
          lt_sel       TYPE usmd_ts_sel,
          ls_sel       TYPE usmd_s_sel,
          lv_readmode  TYPE usmd_readmode_ext  VALUE if_usmd_model_ext=>gc_readmode_default,
          lv_key       LIKE LINE OF it_key.
    FIELD-SYMBOLS: <ls_key> LIKE LINE OF et_key.

    CLEAR: et_key, et_material, es_material.

    cl_usmd_model_ext=>get_instance(
      EXPORTING
        i_usmd_model = 'MM'
      IMPORTING
        eo_instance  = lo_model_ext
    ).
    CHECK: lo_model_ext IS NOT INITIAL.

    ls_sel-fieldname = 'MATERIAL'.
    ls_sel-sign = 'I'.
    ls_sel-option = 'EQ'.

    IF iv_key IS NOT INITIAL.
      ls_sel-low = iv_key.
      INSERT ls_sel INTO TABLE lt_sel.
    ENDIF.

    IF it_key IS NOT INITIAL.
      LOOP AT it_key INTO lv_key.
        ls_sel-low = lv_key.
        INSERT ls_sel INTO TABLE lt_sel.
      ENDLOOP.
    ENDIF.

    IF lt_sel IS INITIAL.
      lt_sel = get_t_sel_from_conv_api( ).
    ENDIF.

    CHECK: lt_sel IS NOT INITIAL.

    IF iv_read_inactive EQ abap_true.
      lv_readmode = if_usmd_model_ext=>gc_readmode_no_act.

      lo_model_ext->read_char_value(
        EXPORTING
          i_fieldname       = 'MATERIAL'
          it_sel            = lt_sel
          i_readmode        = lv_readmode
        IMPORTING
          et_data           = et_key
      ).
      CHECK: et_key IS NOT INITIAL.
      IF lines( lt_sel ) <> lines( et_key ).
        CLEAR: lt_sel.
        LOOP AT et_key ASSIGNING <ls_key>.
          ls_sel-low = <ls_key>-material.
          INSERT ls_sel INTO TABLE lt_sel.
        ENDLOOP.
      ENDIF.

      lv_readmode = if_usmd_model_ext=>gc_readmode_all_inact.
    ENDIF.

    lo_model_ext->read_char_value(
      EXPORTING
        i_fieldname       = 'MATERIAL'
        it_sel            = lt_sel
        i_readmode        = lv_readmode
      IMPORTING
        et_data           = et_material
    ).
    CHECK: et_material IS NOT INITIAL.
    READ TABLE et_material INTO es_material INDEX 1.
    MOVE-CORRESPONDING et_material TO et_key.

    IF et_txt IS SUPPLIED OR gv_debug_mode EQ abap_true.
      lo_model_ext->read_char_value(
        EXPORTING
          i_fieldname       = 'MATERIAL'
          it_sel            = lt_sel
          i_readmode        = lv_readmode
        IMPORTING
          et_data           = et_txt
      ).
    ENDIF.



*    IF et_BSCDATTXT IS SUPPLIED.
*      CLEAR: et_BSCDATTXT.
*      lo_model_ext->read_char_value(
*        EXPORTING
*          i_fieldname       = 'BSCDATTXT'
*          it_sel            = lt_sel
*          i_readmode        = lv_readmode
*        IMPORTING
*          et_data           = et_BSCDATTXT
*      ).
*    ENDIF.
    DEFINE __read.
      IF gv_debug_mode EQ abap_true OR et_&1 IS SUPPLIED.
        CLEAR: et_&1.
        lo_model_ext->read_char_value(
          EXPORTING
            i_fieldname       = '&1'
            it_sel            = lt_sel
            i_readmode        = lv_readmode
          IMPORTING
            et_data           = et_&1
        ).
      ENDIF.
    END-OF-DEFINITION.



    __read bscdattxt.
    __read classasgn.
    __read intcmnt.
    __read marapurch.
    __read maraqtmng.
    __read marasales.
    __read maraspm.
    __read marastor.
    __read marcatp.
    __read marcbasic.
    __read marccstng.
    __read marcfrcst.
    __read marcfrgtr.
    __read marcfrpar.
    __read marcmrpfc.
    __read marcmrpls.
    __read marcmrpmi.
    __read marcmrppp.
    __read marcmrpsp.
    __read marcprt.
    __read marcpurch.
    __read marcqtmng.
    __read marcsales.
    __read marcstore.
    __read marcwrksd.
    __read mardmrp.
    __read mardstor.
    __read mbewactng.
    __read mbewcstng.
    __read mbewmlac.
    __read mbewmlval.
    __read mbewvalua.
    __read mdmabasic.
    __read mean_gtin.
    __read mlanpurch.
    __read mlansales.
    __read mlgnstor.
    __read mlgtstor.
    __read mpgdprodg.
    __read mrptxt.
    __read mvkegrpng.
    __read mvkesales.
    __read purchtxt.
    __read qinsptxt.
    __read qmatbasic.
    __read salestxt.
    __read unitofmsr.
    __read valuation.



    IF gv_debug_mode EQ abap_true.
      BREAK-POINT.
    ENDIF.
  ENDMETHOD.
ENDCLASS.

MDG BP 생성/수정 CR 만드는 로직

Derby — Wed, 15 Dec 2021 09:28:44 +0900

SAP의 가이드 문서 예제에는 Govenence API 를 사용했는데,

FPM UI에서 주로 사용하는 Convenience API 로 만들어 보았습니다.

코드:

FUNCTION ZMDP_CREATE_CR_SUPPL1P1.
*"----------------------------------------------------------------------
*"*"Local Interface:
*"  EXPORTING
*"     REFERENCE(EV_CR) TYPE  USMD_CREQUEST
*"     REFERENCE(EV_ERROR) TYPE  FLAG
*"     REFERENCE(ET_MESSAGE) TYPE  BAPIRET2_TAB
*"----------------------------------------------------------------------
  DATA: lo_mdg_api         TYPE REF TO if_usmd_conv_som_gov_api,
        lt_entity_data     TYPE usmd_gov_api_ts_ent_data,
        ls_entity_data     TYPE usmd_gov_api_s_ent_data,
        lo_cx_usmd_gov_api TYPE REF TO cx_usmd_gov_api,
        ls_message         TYPE bapiret2,
        lv_key_bp_header   TYPE /mdgbp/_s_bp_pp_bp_header-bp_header,
        lv_key_assgnm_id   TYPE /mdgbpx/_s_bp_pp_bp_mlt_as-assgnm_id,
        lv_key_addrno      TYPE /mdgbp/_s_bp_pp_bp_addr-addrno,
        lt_key_bp_header   TYPE TABLE OF /mdgbp/_s_bp_ky_bp_header,
        ls_key_bp_header   TYPE /mdgbp/_s_bp_ky_bp_header,
        lt_key_addrno      TYPE TABLE OF /mdgbp/_s_bp_ky_addrno,
        ls_key_addrno      TYPE /mdgbp/_s_bp_ky_addrno,
        lt_bp_header       TYPE TABLE OF /mdgbp/_s_bp_pp_bp_header,
        ls_bp_header       TYPE /mdgbp/_s_bp_pp_bp_header,
        lt_bp_role         TYPE TABLE OF /mdgbp/_s_bp_pp_bp_role,
        ls_bp_role         TYPE /mdgbp/_s_bp_pp_bp_role,
        lt_bp_mlt_as       TYPE TABLE OF /mdgbpx/_s_bp_pp_bp_mlt_as,
        ls_bp_mlt_as       TYPE /mdgbpx/_s_bp_pp_bp_mlt_as,
        lt_bp_centrl       TYPE TABLE OF /mdgbp/_s_bp_pp_bp_centrl,
        ls_bp_centrl       TYPE /mdgbp/_s_bp_pp_bp_centrl,
        lt_bp_vengen       TYPE TABLE OF /mdgbpx/_s_bp_pp_bp_vengen,
        ls_bp_vengen       TYPE /mdgbpx/_s_bp_pp_bp_vengen,
        lt_bp_porg         TYPE TABLE OF /mdgbpx/_s_bp_pp_bp_porg,
        ls_bp_porg         TYPE /mdgbpx/_s_bp_pp_bp_porg,
        lt_bp_mlt_ad       TYPE TABLE OF /mdgbpx/_s_bp_pp_bp_mlt_ad,
        ls_bp_mlt_ad       TYPE /mdgbpx/_s_bp_pp_bp_mlt_ad,
        lt_address         TYPE TABLE OF /mdgbp/_s_bp_pp_address,
        ls_address         TYPE /mdgbp/_s_bp_pp_address,
        lt_bp_addr         TYPE TABLE OF /mdgbp/_s_bp_pp_bp_addr,
        ls_bp_addr         TYPE /mdgbp/_s_bp_pp_bp_addr,
        lt_bp_addusg       TYPE TABLE OF /mdgbp/_s_bp_pp_bp_addusg,
        ls_bp_addusg       TYPE /mdgbp/_s_bp_pp_bp_addusg,
        lt_ad_name_o       TYPE TABLE OF /mdgbp/_s_bp_pp_ad_name_o,
        ls_ad_name_o       TYPE /mdgbp/_s_bp_pp_ad_name_o,
        lt_ad_postal       TYPE TABLE OF /mdgbp/_s_bp_pp_ad_postal,
        ls_ad_postal       TYPE /mdgbp/_s_bp_pp_ad_postal,
        lt_ad_tel          TYPE TABLE OF /mdgbp/_s_bp_pp_ad_tel,
        ls_ad_tel          TYPE /mdgbp/_s_bp_pp_ad_tel,
        lt_ad_fax          TYPE TABLE OF /mdgbp/_s_bp_pp_ad_fax,
        ls_ad_fax          TYPE /mdgbp/_s_bp_pp_ad_fax,
        lt_ad_url          TYPE TABLE OF /mdgbp/_s_bp_pp_ad_url,
        ls_ad_url          TYPE /mdgbp/_s_bp_pp_ad_url,
        lv_index           TYPE i.

  CLEAR: ev_cr, ev_error, et_message.

  TRY.
********************************************************************************************
* 초기화.
********************************************************************************************
      cl_usmd_conv_som_gov_api=>get_instance(
        EXPORTING
          iv_model_name = 'BP'
        RECEIVING
          ro_so_gov_api = lo_mdg_api
      ).

      lo_mdg_api->refresh_buffers( ).
      lo_mdg_api->set_environment(
        EXPORTING
          iv_crequest_type   = 'SUPPL1P1'
          iv_process         = 'SUP1'
          iv_create_crequest = abap_true
      ).
      lo_mdg_api->set_crequest_attributes(
        EXPORTING
          iv_crequest_text   = |공급업체 생성 { sy-datum }|
      ).
      lo_mdg_api->enqueue_crequest( iv_lock_mode = 'E' ).




********************************************************************************************
* BP_HEADER
********************************************************************************************
      lo_mdg_api->create_entity_tmp_key(
        EXPORTING
          iv_entity = 'BP_HEADER'
        IMPORTING
          es_key    = ls_key_bp_header
      ).
      lv_key_bp_header = ls_key_bp_header-bp_header.

      CLEAR: ls_bp_header.
      ls_bp_header-bp_header = lv_key_bp_header.
      ls_bp_header-bp_guid = cl_system_uuid=>create_uuid_x16_static( ).
      ls_bp_header-bu_group = '0001'.
      ls_bp_header-bu_type = '2'.
      ls_bp_header-txtlg = 'test'.
      INSERT ls_bp_header INTO TABLE lt_bp_header.

      PERFORM write_entity USING lo_mdg_api 'BP_HEADER' lt_bp_header.

********************************************************************************************
* BP_ROLE
********************************************************************************************
      CLEAR: ls_bp_role.
      ls_bp_role-bp_header = lv_key_bp_header.
      ls_bp_role-bp_rol_id = 'FLVN01'.
      INSERT ls_bp_role INTO TABLE lt_bp_role.

      PERFORM write_entity USING lo_mdg_api 'BP_ROLE' lt_bp_role.

********************************************************************************************
* BP_MLT_AS
********************************************************************************************
      lv_key_assgnm_id = 1.
      CLEAR: ls_bp_mlt_as.
      ls_bp_mlt_as-bp_header = lv_key_bp_header.
      ls_bp_mlt_as-assgnm_id = lv_key_assgnm_id.
      ls_bp_mlt_as-as_type = 'SUPPL'.
      ls_bp_mlt_as-object_id = lv_key_bp_header.
      ls_bp_mlt_as-standard = abap_true.
      INSERT ls_bp_mlt_as INTO TABLE lt_bp_mlt_as.

      PERFORM write_entity USING lo_mdg_api 'BP_MLT_AS' lt_bp_mlt_as.

*********************************************************************************************
* ADDRNO
*********************************************************************************************
      lo_mdg_api->create_entity_tmp_key(
        EXPORTING
          iv_entity = 'ADDRNO'
        IMPORTING
          es_key    = ls_key_addrno
      ).
      lv_key_addrno = ls_key_addrno-addrno.

      INSERT ls_key_addrno INTO TABLE lt_key_addrno.

      PERFORM write_entity USING lo_mdg_api 'ADDRNO' lt_key_addrno.

*********************************************************************************************
* BP_MLT_AD
*********************************************************************************************
      CLEAR: ls_bp_mlt_ad.
      ls_bp_mlt_ad-addrno = 'XXDEFAULT'.
      ls_bp_mlt_ad-assgnm_id = lv_key_assgnm_id.
      ls_bp_mlt_ad-bp_header = lv_key_bp_header.
      INSERT ls_bp_mlt_ad INTO TABLE lt_bp_mlt_ad.

      PERFORM write_entity USING lo_mdg_api 'BP_MLT_AD' lt_bp_mlt_ad.

*********************************************************************************************
* ADDRESS
*********************************************************************************************
      CLEAR: ls_address.
      ls_address-bp_header = lv_key_bp_header.
      ls_address-addrno = lv_key_addrno.
      ls_address-type = 1.
      INSERT ls_address INTO TABLE lt_address.

      PERFORM write_entity USING lo_mdg_api 'ADDRESS' lt_address.

*********************************************************************************************
* BP_ADDR
*********************************************************************************************
      CLEAR: ls_bp_addr.
      ls_bp_addr-bp_header = lv_key_bp_header.
      ls_bp_addr-addrno = lv_key_addrno.
      ls_bp_addr-addr_guid = cl_system_uuid=>create_uuid_x16_static( ).
      INSERT ls_bp_addr INTO TABLE lt_bp_addr.

      PERFORM write_entity USING lo_mdg_api 'BP_ADDR' lt_bp_addr.

*********************************************************************************************
* BP_ADDUSG
*********************************************************************************************
      CLEAR: ls_bp_addusg.
      ls_bp_addusg-bp_header = lv_key_bp_header.
      ls_bp_addusg-addrno = lv_key_addrno.
      ls_bp_addusg-bp_adrknd = 'XXDEFAULT'.
      INSERT ls_bp_addusg INTO TABLE lt_bp_addusg.

      PERFORM write_entity USING lo_mdg_api 'BP_ADDUSG' lt_bp_addusg.

*********************************************************************************************
* AD_POSTAL
*********************************************************************************************
      CLEAR: ls_ad_postal.
      ls_ad_postal-bp_header = lv_key_bp_header.
      ls_ad_postal-addrno = lv_key_addrno.
      ls_ad_postal-ref_posta = 'KR'.
      ls_ad_postal-langu_com = '3'.
      ls_ad_postal-post_cod1 = '12345'.
      ls_ad_postal-city1 = '주소1'.
      ls_ad_postal-street = '주소2'.
      INSERT ls_ad_postal INTO TABLE lt_ad_postal.

      PERFORM write_entity USING lo_mdg_api 'AD_POSTAL' lt_ad_postal.

*AD_URL 인터넷 주소
*AD_TEL 전화번호
*AD_FAX 팩스번호
*AD_EMAIL 전자메일 주소

********************************************************************************************
* BP_CENTRL
********************************************************************************************
      CLEAR: ls_bp_centrl.
      ls_bp_centrl-bp_header = lv_key_bp_header.
*      ls_bp_centrl-bpkind = 'P001'.
*      ls_bp_centrl-title_bp = '0003'.
      ls_bp_centrl-name_org1 = 'test'.
      INSERT ls_bp_centrl INTO TABLE lt_bp_centrl.

      PERFORM write_entity USING lo_mdg_api 'BP_CENTRL' lt_bp_centrl.

********************************************************************************************
* BP_VENGEN
********************************************************************************************
      CLEAR: ls_bp_vengen.
      ls_bp_vengen-assgnm_id = lv_key_assgnm_id.
      ls_bp_vengen-bp_header = lv_key_bp_header.
      ls_bp_vengen-lifnr = lv_key_bp_header.
      ls_bp_vengen-ktokk = 'A000'.
      INSERT ls_bp_vengen INTO TABLE lt_bp_vengen.

      PERFORM write_entity USING lo_mdg_api 'BP_VENGEN' lt_bp_vengen.

**********************************************************************
*BP_PORG
**********************************************************************
      CLEAR: ls_bp_porg.
      ls_bp_porg-assgnm_id = lv_key_assgnm_id.
      ls_bp_porg-bp_header = lv_key_bp_header.
      ls_bp_porg-prch_org = '1100'.
      INSERT ls_bp_porg INTO TABLE lt_bp_porg.

      CLEAR: ls_bp_porg.
      ls_bp_porg-assgnm_id = lv_key_assgnm_id.
      ls_bp_porg-bp_header = lv_key_bp_header.
      ls_bp_porg-prch_org = '1200'.
      INSERT ls_bp_porg INTO TABLE lt_bp_porg.

      PERFORM write_entity USING lo_mdg_api 'BP_PORG' lt_bp_porg.



*VENGENTXT 텍스트(공급업체 일반 데이터)
*BP_VENVAL 공급업체: 특징 값(분류)
*BP_VENSUB 공급업체 하위 범위
*BP_VENDDB 문서 링크에 대한 기본 데이터
*BP_VENCLA 공급업체: 클래스 지정(분류)
*BP_TAXGRP 세금 그룹화(공급업체)
*BP_COMPNY 회사 코드




********************************************************************************************
* 저장.
********************************************************************************************
      lo_mdg_api->confirm_entity_data( ).
      lo_mdg_api->check( ).
      IF lo_mdg_api->mv_successfully_checked EQ abap_true.
        lo_mdg_api->set_action( cl_usmd_crequest_action=>gc_draft_action-submit ).
        lo_mdg_api->save( ).
        ev_cr = lo_mdg_api->mv_crequest_id.
      ENDIF.

    CATCH cx_uuid_error.
    CATCH cx_usmd_gov_api INTO lo_cx_usmd_gov_api.
      ev_error = abap_true.
  ENDTRY.


  PERFORM get_message USING lo_mdg_api et_message.
  lo_mdg_api->dequeue_entity_all( ).
  lo_mdg_api->dequeue_crequest( ).
  lo_mdg_api->refresh_buffers( ).


ENDFUNCTION.

FUNCTION ZMDP_CREATE_CR_SUPPL2P1.
*"----------------------------------------------------------------------
*"*"Local Interface:
*"  IMPORTING
*"     REFERENCE(IV_BP_ID) TYPE  BU_BUSINESSPARTNER
*"  EXPORTING
*"     REFERENCE(EV_CR) TYPE  USMD_CREQUEST
*"     REFERENCE(EV_ERROR) TYPE  FLAG
*"     REFERENCE(ET_MESSAGE) TYPE  BAPIRET2_TAB
*"----------------------------------------------------------------------
  DATA: lo_mdg_api         TYPE REF TO if_usmd_conv_som_gov_api,
        lo_usmd_model      TYPE REF TO if_usmd_model_ext,
        lt_sel             TYPE usmd_ts_sel,
        lo_cx_usmd_gov_api TYPE REF TO cx_usmd_gov_api,
        ls_message         TYPE bapiret2,
        lv_key_bp_header   TYPE /mdgbp/_s_bp_pp_bp_header-bp_header,
        lv_key_assgnm_id   TYPE /mdgbpx/_s_bp_pp_bp_mlt_as-assgnm_id,
        lv_key_addrno      TYPE /mdgbp/_s_bp_pp_bp_addr-addrno,
        lt_key_bp_header   TYPE TABLE OF /mdgbp/_s_bp_ky_bp_header,
        ls_key_bp_header   TYPE /mdgbp/_s_bp_ky_bp_header,
        lt_key_addrno      TYPE TABLE OF /mdgbp/_s_bp_ky_addrno,
        ls_key_addrno      TYPE /mdgbp/_s_bp_ky_addrno,
        lt_bp_header       TYPE TABLE OF /mdgbp/_s_bp_pp_bp_header,
        ls_bp_header       TYPE /mdgbp/_s_bp_pp_bp_header,
        lt_bp_role         TYPE TABLE OF /mdgbp/_s_bp_pp_bp_role,
        ls_bp_role         TYPE /mdgbp/_s_bp_pp_bp_role,
        lt_bp_mlt_as       TYPE TABLE OF /mdgbpx/_s_bp_pp_bp_mlt_as,
        ls_bp_mlt_as       TYPE /mdgbpx/_s_bp_pp_bp_mlt_as,
        lt_bp_centrl       TYPE TABLE OF /mdgbp/_s_bp_pp_bp_centrl,
        ls_bp_centrl       TYPE /mdgbp/_s_bp_pp_bp_centrl,
        lt_bp_vengen       TYPE TABLE OF /mdgbpx/_s_bp_pp_bp_vengen,
        ls_bp_vengen       TYPE /mdgbpx/_s_bp_pp_bp_vengen,
        lt_bp_porg         TYPE TABLE OF /mdgbpx/_s_bp_pp_bp_porg,
        ls_bp_porg         TYPE /mdgbpx/_s_bp_pp_bp_porg,
        lt_bp_mlt_ad       TYPE TABLE OF /mdgbpx/_s_bp_pp_bp_mlt_ad,
        ls_bp_mlt_ad       TYPE /mdgbpx/_s_bp_pp_bp_mlt_ad,
        lt_address         TYPE TABLE OF /mdgbp/_s_bp_pp_address,
        ls_address         TYPE /mdgbp/_s_bp_pp_address,
        lt_bp_addr         TYPE TABLE OF /mdgbp/_s_bp_pp_bp_addr,
        ls_bp_addr         TYPE /mdgbp/_s_bp_pp_bp_addr,
        lt_bp_addusg       TYPE TABLE OF /mdgbp/_s_bp_pp_bp_addusg,
        ls_bp_addusg       TYPE /mdgbp/_s_bp_pp_bp_addusg,
        lt_ad_name_o       TYPE TABLE OF /mdgbp/_s_bp_pp_ad_name_o,
        ls_ad_name_o       TYPE /mdgbp/_s_bp_pp_ad_name_o,
        lt_ad_postal       TYPE TABLE OF /mdgbp/_s_bp_pp_ad_postal,
        ls_ad_postal       TYPE /mdgbp/_s_bp_pp_ad_postal,
        lt_ad_tel          TYPE TABLE OF /mdgbp/_s_bp_pp_ad_tel,
        ls_ad_tel          TYPE /mdgbp/_s_bp_pp_ad_tel,
        lt_ad_fax          TYPE TABLE OF /mdgbp/_s_bp_pp_ad_fax,
        ls_ad_fax          TYPE /mdgbp/_s_bp_pp_ad_fax,
        lt_ad_url          TYPE TABLE OF /mdgbp/_s_bp_pp_ad_url,
        ls_ad_url          TYPE /mdgbp/_s_bp_pp_ad_url,
        lv_index           TYPE i.

  CLEAR: ev_cr, ev_error, et_message.

  TRY.
********************************************************************************************
* 초기화.
********************************************************************************************
      cl_usmd_conv_som_gov_api=>get_instance(
        EXPORTING
          iv_model_name = 'BP'
        RECEIVING
          ro_so_gov_api = lo_mdg_api
      ).
      cl_usmd_model_ext=>get_instance(
        EXPORTING
          i_usmd_model = 'BP'
        IMPORTING
          eo_instance  = lo_usmd_model
      ).
      lv_key_bp_header = iv_bp_id.
      lt_sel = VALUE #( ( fieldname = 'BP_HEADER' sign = 'I' option = 'EQ' low = lv_key_bp_header ) ).

********************************************************************************************
* BP_HEADER
********************************************************************************************
      PERFORM read_entity USING lo_usmd_model 'BP_HEADER' lt_sel lt_bp_header.
      IF lt_bp_header IS INITIAL.
        " IV_BP_ID 에 해당하는 BP가 없음. 에러 처리.
        ev_error = abap_true.
        RETURN.
      ENDIF.

********************************************************************************************
* BP_MLT_AS
********************************************************************************************
      PERFORM read_entity USING lo_usmd_model 'BP_MLT_AS' lt_sel lt_bp_mlt_as.
      READ TABLE lt_bp_mlt_as INTO ls_bp_mlt_as WITH KEY as_type = 'SUPPL'.
      IF sy-subrc EQ 0.
        lv_key_assgnm_id = ls_bp_mlt_as-assgnm_id.
      ELSE.
        " C/V 유형 다름. 에러 처리.
        ev_error = abap_true.
        RETURN.
      ENDIF.


********************************************************************************************
* CR 생성
********************************************************************************************
      lo_mdg_api->refresh_buffers( ).
      lo_mdg_api->set_environment(
        EXPORTING
          iv_crequest_type   = 'SUPPL2P1'
          iv_process         = 'SUP2'
          iv_create_crequest = abap_true
      ).
      lo_mdg_api->set_crequest_attributes(
        EXPORTING
          iv_crequest_text   = |공급업체 변경 { sy-datum }|
      ).
      lo_mdg_api->enqueue_crequest( iv_lock_mode = 'E' ).

      ls_key_bp_header-bp_header = lv_key_bp_header.
      APPEND ls_key_bp_header TO lt_key_bp_header.
      lo_mdg_api->enqueue_entity( VALUE #( ( entity = 'BP_HEADER' tabl = REF #( lt_key_bp_header ) ) ) ).

********************************************************************************************
* BP_ROLE
********************************************************************************************
      PERFORM read_entity USING lo_usmd_model 'BP_ROLE' lt_sel lt_bp_role.
      PERFORM write_entity USING lo_mdg_api 'BP_ROLE' lt_bp_role.

*********************************************************************************************
* BP_ADDR
*********************************************************************************************

      PERFORM read_entity USING lo_usmd_model 'BP_ADDR' lt_sel lt_bp_addr.
      IF lt_bp_addr IS NOT INITIAL.
        READ TABLE lt_bp_addr INTO ls_bp_addr INDEX 1.
        lv_key_addrno = ls_bp_addr-addrno.
        ls_key_addrno-addrno = lv_key_addrno.
        INSERT ls_key_addrno INTO TABLE lt_key_addrno.
      ELSE.
        " 기존에 주소가 없는 경우.
        lo_mdg_api->create_entity_tmp_key(
          EXPORTING
            iv_entity = 'ADDRNO'
          IMPORTING
            es_key    = ls_key_addrno
        ).
        lv_key_addrno = ls_key_addrno-addrno.
        INSERT ls_key_addrno INTO TABLE lt_key_addrno.
        PERFORM write_entity USING lo_mdg_api 'ADDRNO' lt_key_addrno.

        CLEAR: ls_bp_addr.
        ls_bp_addr-bp_header = lv_key_bp_header.
        ls_bp_addr-addrno = lv_key_addrno.
        ls_bp_addr-addr_guid = cl_system_uuid=>create_uuid_x16_static( ).
        INSERT ls_bp_addr INTO TABLE lt_bp_addr.
        PERFORM write_entity USING lo_mdg_api 'BP_ADDR' lt_bp_addr.

        CLEAR: ls_bp_addusg.
        ls_bp_addusg-bp_header = lv_key_bp_header.
        ls_bp_addusg-addrno = lv_key_addrno.
        ls_bp_addusg-bp_adrknd = 'XXDEFAULT'.
        INSERT ls_bp_addusg INTO TABLE lt_bp_addusg.
        PERFORM write_entity USING lo_mdg_api 'BP_ADDUSG' lt_bp_addusg.

        CLEAR: ls_address.
        ls_address-bp_header = lv_key_bp_header.
        ls_address-addrno = lv_key_addrno.
        ls_address-type = 1.
        INSERT ls_address INTO TABLE lt_address.
        PERFORM write_entity USING lo_mdg_api 'ADDRESS' lt_address.

      ENDIF.

*********************************************************************************************
* BP_MLT_AD
*********************************************************************************************
      PERFORM read_entity USING lo_usmd_model 'BP_MLT_AD' lt_sel lt_bp_mlt_ad.
      PERFORM write_entity USING lo_mdg_api 'BP_MLT_AD' lt_bp_mlt_ad.

*********************************************************************************************
* AD_POSTAL
*********************************************************************************************
      PERFORM read_entity USING lo_usmd_model 'AD_POSTAL' lt_sel lt_ad_postal.
      LOOP AT lt_ad_postal INTO ls_ad_postal.
        ls_ad_postal-ref_posta = 'KR'.
        MODIFY lt_ad_postal FROM ls_ad_postal.
      ENDLOOP.
      PERFORM write_entity USING lo_mdg_api 'AD_POSTAL' lt_ad_postal.

*AD_URL 인터넷 주소
*AD_TEL 전화번호
*AD_FAX 팩스번호
*AD_EMAIL 전자메일 주소

********************************************************************************************
* BP_CENTRL
********************************************************************************************
      PERFORM read_entity USING lo_usmd_model 'BP_CENTRL' lt_sel lt_bp_centrl.
      PERFORM write_entity USING lo_mdg_api 'BP_CENTRL' lt_bp_centrl.

********************************************************************************************
* BP_VENGEN
********************************************************************************************
      PERFORM read_entity USING lo_usmd_model 'BP_VENGEN' lt_sel lt_bp_vengen.
      PERFORM write_entity USING lo_mdg_api 'BP_VENGEN' lt_bp_vengen.

**********************************************************************
*BP_PORG
**********************************************************************
      PERFORM read_entity USING lo_usmd_model 'BP_PORG' lt_sel lt_bp_porg.
      PERFORM write_entity USING lo_mdg_api 'BP_PORG' lt_bp_porg.



*VENGENTXT 텍스트(공급업체 일반 데이터)
*BP_VENVAL 공급업체: 특징 값(분류)
*BP_VENSUB 공급업체 하위 범위
*BP_VENDDB 문서 링크에 대한 기본 데이터
*BP_VENCLA 공급업체: 클래스 지정(분류)
*BP_TAXGRP 세금 그룹화(공급업체)
*BP_COMPNY 회사 코드




********************************************************************************************
* 저장.
********************************************************************************************
      lo_mdg_api->confirm_entity_data( ).
      lo_mdg_api->check( ).
      IF lo_mdg_api->mv_successfully_checked EQ abap_true.
        lo_mdg_api->set_action( cl_usmd_crequest_action=>gc_draft_action-submit ).
        lo_mdg_api->save( ).
        ev_cr = lo_mdg_api->mv_crequest_id.
      ENDIF.

    CATCH cx_uuid_error.
    CATCH cx_usmd_gov_api INTO lo_cx_usmd_gov_api.
      ev_error = abap_true.
  ENDTRY.


  PERFORM get_message USING lo_mdg_api et_message.
  lo_mdg_api->dequeue_entity_all( ).
  lo_mdg_api->dequeue_crequest( ).
  lo_mdg_api->refresh_buffers( ).


ENDFUNCTION.


FUNCTION zmdp_conv_usmdmsg_to_bapiret2.
*"----------------------------------------------------------------------
*"*"Local Interface:
*"  IMPORTING
*"     REFERENCE(IS_USMDMSG) TYPE  USMD_S_MESSAGE
*"  EXPORTING
*"     REFERENCE(ES_BAPIRET2) TYPE  BAPIRET2
*"----------------------------------------------------------------------
  CLEAR: es_bapiret2.

  MESSAGE ID is_usmdmsg-msgid TYPE is_usmdmsg-msgty NUMBER is_usmdmsg-msgno
    WITH is_usmdmsg-msgv1 is_usmdmsg-msgv2 is_usmdmsg-msgv3 is_usmdmsg-msgv4
    INTO es_bapiret2-message.


  es_bapiret2-type = sy-msgty.
  es_bapiret2-id = sy-msgid.
  es_bapiret2-number = sy-msgno.
  es_bapiret2-message_v1 = sy-msgv1.
  es_bapiret2-message_v2 = sy-msgv2.
  es_bapiret2-message_v3 = sy-msgv3.
  es_bapiret2-message_v4 = sy-msgv4.
  es_bapiret2-row = is_usmdmsg-row.
  es_bapiret2-field = is_usmdmsg-fieldname.

ENDFUNCTION.



FORM write_entity USING io_mdg_api iv_entity it_data.
  DATA: lo_mdg_api     TYPE REF TO if_usmd_conv_som_gov_api,
        lt_entity_data TYPE usmd_gov_api_ts_ent_data,
        ls_entity_data TYPE usmd_gov_api_s_ent_data.

  lo_mdg_api = io_mdg_api.

  CLEAR: lt_entity_data, ls_entity_data.
  ls_entity_data-entity = iv_entity.
  ls_entity_data-entity_data = REF #( it_data ).
  APPEND ls_entity_data TO lt_entity_data.

  lo_mdg_api->write_entity_data( it_entity_data = lt_entity_data ).
ENDFORM.
FORM read_entity USING io_usmd_model iv_entity it_sel et_data.
  DATA: lo_usmd_model  TYPE REF TO if_usmd_model_ext.

  lo_usmd_model = io_usmd_model.
  lo_usmd_model->read_char_value(
    EXPORTING
      i_fieldname       = iv_entity
      it_sel            = it_sel
      if_no_flush       = abap_true
    IMPORTING
      et_data           = et_data
  ).
ENDFORM.
FORM get_message USING io_mdg_api TYPE REF TO if_usmd_conv_som_gov_api
                       et_message TYPE bapiret2_tab.
  DATA: lt_usmd_msg TYPE usmd_t_message,
        ls_usmd_msg TYPE usmd_s_message,
        ls_bapiret2 TYPE bapiret2.

  lt_usmd_msg = io_mdg_api->get_messages( ).

  LOOP AT lt_usmd_msg INTO ls_usmd_msg.
    IF ls_usmd_msg-msgid EQ 'MDG_BS_BP' AND ls_usmd_msg-msgno EQ '057'.
      " 필요 없는 메시지.
      CONTINUE.
    ENDIF.
    CALL FUNCTION 'ZMDP_CONV_USMDMSG_TO_BAPIRET2'
      EXPORTING
        is_usmdmsg  = ls_usmd_msg
      IMPORTING
        es_bapiret2 = ls_bapiret2.
    APPEND ls_bapiret2 TO et_message.
  ENDLOOP.

ENDFORM.

abapGit 활용 - 패키지(개발클래스) 전체 삭제

Derby — Thu, 15 Jul 2021 22:27:26 +0900

패키지를 내부 오브젝트 포함하여 한방에 삭제하는 방법이 없습니다.

abapGit을 사용하면 가능한데요.

KR_POSTCODE : 한국주소입력 Version 2.0

Derby — Fri, 9 Jul 2021 13:46:49 +0900

https://github.com/boy0korea/KR_POSTCODE

boy0korea/KR_POSTCODE

South Korea Postal Code in ABAP & WDA & FPM. Contribute to boy0korea/KR_POSTCODE development by creating an account on GitHub.

github.com

KR_POSTCODE 는 SAP용 주소입력 API 입니다.

다음주소API 화면을 ABAP(or WDA or FPM) 에서 호출 하고 결과를 받을 수 있습니다.

스탠다드 주소 입력 부분을 enhnace 했기 때문에 KR 국가 선택시 서치헬프로 입력할 수 있습니다.